pkgs/by-name/pa/parted/package.nix

   1 { lib, stdenv
   2 , fetchurl
   3 , lvm2
   4 , libuuid
   5 , gettext
   6 , readline
   7 , dosfstools
   8 , e2fsprogs
   9 , perl
  10 , python3
  11 , util-linux
  12 , check
  13 , enableStatic ? stdenv.hostPlatform.isStatic
  14 }:
  15
  16 stdenv.mkDerivation rec {
  17   pname = "parted";
  18   version = "3.6";
  19
  20   src = fetchurl {
  21     url = "mirror://gnu/parted/parted-${version}.tar.xz";
  22     sha256 = "sha256-O0Pb4zzKD5oYYB66tWt4UrEo7Bo986mzDM3l5zNZ5hI=";
  23   };
  24
  25   outputs = [ "out" "dev" "man" "info" ];
  26
  27   postPatch = ''
  28     patchShebangs tests
  29   '';
  30
  31   buildInputs = [ libuuid ]
  32     ++ lib.optional (readline != null) readline
  33     ++ lib.optional (gettext != null) gettext
  34     ++ lib.optional (lvm2 != null) lvm2;
  35
  36   configureFlags =
  37        (if (readline != null)
  38         then [ "--with-readline" ]
  39         else [ "--without-readline" ])
  40     ++ lib.optional (lvm2 == null) "--disable-device-mapper"
  41     ++ lib.optional enableStatic "--enable-static";
  42
  43   # Tests were previously failing due to Hydra running builds as uid 0.
  44   # That should hopefully be fixed now.
  45   doCheck = !stdenv.hostPlatform.isMusl; /* translation test */
  46   nativeCheckInputs = [ check dosfstools e2fsprogs perl python3 util-linux ];
  47
  48   meta = {
  49     description = "Create, destroy, resize, check, and copy partitions";
  50
  51     longDescription = ''
  52       GNU Parted is an industrial-strength package for creating, destroying,
  53       resizing, checking and copying partitions, and the file systems on
  54       them.  This is useful for creating space for new operating systems,
  55       reorganising disk usage, copying data on hard disks and disk imaging.
  56
  57       It contains a library, libparted, and a command-line frontend, parted,
  58       which also serves as a sample implementation and script backend.
  59     '';
  60
  61     homepage = "https://www.gnu.org/software/parted/";
  62     license = lib.licenses.gpl3Plus;
  63
  64     maintainers = [
  65       # Add your name here!
  66     ];
  67
  68     # GNU Parted requires libuuid, which is part of util-linux-ng.
  69     platforms = lib.platforms.linux;
  70   };
  71 }