pkgs/by-name/py/pyrosimple/package.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , nix-update-script
   5 , pyrosimple
   6 , python3
   7 , testers
   8 , withInotify ? stdenv.hostPlatform.isLinux
   9 }:
  10
  11 python3.pkgs.buildPythonApplication rec {
  12   pname = "pyrosimple";
  13   version = "2.14.0";
  14   format = "pyproject";
  15
  16   src = fetchFromGitHub {
  17     owner = "kannibalox";
  18     repo = pname;
  19     rev = "refs/tags/v${version}";
  20     hash = "sha256-lEtyt7i8MyL2VffxNFQkL9RkmGeo6Nof0AOQwf6BUSE=";
  21   };
  22
  23   pythonRelaxDeps = [
  24     "prometheus-client"
  25     "python-daemon"
  26   ];
  27
  28   nativeBuildInputs = with python3.pkgs; [
  29     poetry-core
  30   ];
  31
  32   propagatedBuildInputs = with python3.pkgs; [
  33     bencode-py
  34     apscheduler
  35     jinja2
  36     python-daemon
  37     importlib-resources
  38     parsimonious
  39     prometheus-client
  40     prompt-toolkit
  41     requests
  42     shtab
  43     python-box
  44     tomli-w
  45   ] ++ lib.optionals (pythonOlder "3.11") [
  46     tomli
  47   ] ++ lib.optional withInotify inotify;
  48
  49   nativeCheckInputs = with python3.pkgs; [
  50     pytestCheckHook
  51   ];
  52
  53   passthru = {
  54     updateScript = nix-update-script { };
  55     tests = testers.testVersion {
  56       package = pyrosimple;
  57       command = "pyroadmin --version";
  58     };
  59   };
  60
  61   meta = with lib; {
  62     description = "RTorrent client";
  63     homepage = "https://kannibalox.github.io/pyrosimple/";
  64     changelog = "https://github.com/kannibalox/pyrosimple/blob/v${version}/CHANGELOG.md";
  65     license = licenses.gpl3Plus;
  66     maintainers = with maintainers; [ ne9z vamega ];
  67   };
  68 }