pkgs/by-name/sk/skim/package.nix

   1 { lib
   2 , stdenv
   3 , fetchCrate
   4 , rustPlatform
   5 , installShellFiles
   6 }:
   7
   8 rustPlatform.buildRustPackage rec {
   9   pname = "skim";
  10   version = "0.10.4";
  11
  12   src = fetchCrate {
  13     inherit pname version;
  14     hash = "sha256-C2yK+SO8Tpw3BxXXu1jeDzYJ2548RZa7NFWaE0SdNJ0=";
  15   };
  16
  17   nativeBuildInputs = [ installShellFiles ];
  18
  19   outputs = [ "out" "vim" ];
  20
  21   cargoHash = "sha256-jBcgoWbmBOgU7M71lr4OXOe2S6NAXl+I8D+ZtT45Vos=";
  22
  23   postPatch = ''
  24     sed -i -e "s|expand('<sfile>:h:h')|'$out'|" plugin/skim.vim
  25   '';
  26
  27   postInstall = ''
  28     install -D -m 555 bin/sk-tmux -t $out/bin
  29
  30     install -D -m 444 plugin/skim.vim -t $vim/plugin
  31
  32     install -D -m 444 shell/* -t $out/share/skim
  33
  34     installManPage man/man1/*
  35
  36     cat <<SCRIPT > $out/bin/sk-share
  37     #! ${stdenv.shell}
  38     # Run this script to find the skim shared folder where all the shell
  39     # integration scripts are living.
  40     echo $out/share/skim
  41     SCRIPT
  42     chmod +x $out/bin/sk-share
  43   '';
  44
  45   # https://github.com/lotabout/skim/issues/440
  46   doCheck = !stdenv.hostPlatform.isAarch64;
  47
  48   meta = with lib; {
  49     description = "Command-line fuzzy finder written in Rust";
  50     homepage = "https://github.com/lotabout/skim";
  51     license = licenses.mit;
  52     mainProgram = "sk";
  53     maintainers = with maintainers; [ dywedir ];
  54   };
  55 }