pkgs/by-name/sy/sympa/package.nix

   1 { lib, stdenv, perl, fetchFromGitHub, autoreconfHook, nixosTests }:
   2
   3 let
   4   dataDir = "/var/lib/sympa";
   5   runtimeDir = "/run/sympa";
   6   perlEnv = perl.withPackages (p: with p; [
   7     ArchiveZip
   8     CGI
   9     CGIFast
  10     ClassSingleton
  11     DateTime
  12     DBI
  13     DateTimeFormatMail
  14     DateTimeTimeZone
  15     Encode
  16     FCGI
  17     FileCopyRecursive
  18     FileNFSLock
  19     FilePath
  20     HTMLParser
  21     HTMLFormatter
  22     HTMLTree
  23     HTMLStripScriptsParser
  24     IO
  25     IOStringy
  26     LWP
  27     libintl-perl
  28
  29     MHonArc
  30     MIMECharset
  31     MIMETools
  32     MIMEEncWords
  33     MIMELiteHTML
  34     MailTools
  35     NetCIDR
  36     ScalarListUtils
  37     SysSyslog
  38     TermProgressBar
  39     TemplateToolkit
  40     URI
  41     UnicodeLineBreak
  42     XMLLibXML
  43
  44     ### Features
  45     Clone
  46     CryptEksblowfish
  47
  48     DBDPg
  49     DBDSQLite
  50     DBDmysql
  51
  52     DataPassword
  53     EncodeLocale
  54     IOSocketSSL
  55     MailDKIM
  56     NetDNS
  57     perlldap
  58     libnet
  59     SOAPLite
  60   ]);
  61 in
  62 stdenv.mkDerivation rec {
  63   pname = "sympa";
  64   version = "6.2.72";
  65
  66   src = fetchFromGitHub {
  67     owner = "sympa-community";
  68     repo = pname;
  69     rev = version;
  70     sha256 = "sha256-8G6MxpqVa3E5J/68E7tljcXF4w7OmNkI0nJwsgxJE28=";
  71   };
  72
  73   configureFlags = [
  74     "--enable-fhs"
  75     "--without-initdir"
  76     "--without-unitsdir"
  77     "--without-smrshdir"
  78
  79     "--with-lockdir=${runtimeDir}"
  80     "--with-piddir=${runtimeDir}"
  81     "--with-confdir=${dataDir}/etc"
  82     "--sysconfdir=${dataDir}/etc"
  83     "--with-spooldir=${dataDir}/spool"
  84     "--with-expldir=${dataDir}/list_data"
  85   ];
  86   nativeBuildInputs = [ autoreconfHook ];
  87   buildInputs = [ perlEnv ];
  88   patches = [ ./make-docs.patch ];
  89
  90   prePatch = ''
  91     patchShebangs po/sympa/add-lang.pl
  92   '';
  93
  94   preInstall = ''
  95     mkdir "$TMP/bin"
  96     for i in chown chgrp chmod; do
  97       echo '#!${stdenv.shell}' >> "$TMP/bin/$i"
  98       chmod +x "$TMP/bin/$i"
  99     done
 100     PATH="$TMP/bin:$PATH"
 101   '';
 102
 103   postInstall = ''
 104     rm -rf "$TMP/bin"
 105   '';
 106
 107   passthru.tests = {
 108     inherit (nixosTests) sympa;
 109   };
 110
 111   meta = with lib; {
 112     description = "Open source mailing list manager";
 113     homepage = "https://www.sympa.org";
 114     license = licenses.gpl2Plus;
 115     maintainers = with maintainers; [ sorki mmilata ];
 116     platforms = platforms.all;
 117   };
 118 }