pkgs/by-name/ti/tinymist/package.nix

   1 {
   2   lib,
   3   rustPlatform,
   4   fetchFromGitHub,
   5   pkg-config,
   6   libgit2,
   7   openssl,
   8   zlib,
   9   stdenv,
  10   darwin,
  11   versionCheckHook,
  12   nix-update-script,
  13   vscode-extensions,
  14 }:
  15
  16 rustPlatform.buildRustPackage rec {
  17   pname = "tinymist";
  18   # Please update the corresponding vscode extension when updating
  19   # this derivation.
  20   version = "0.12.0";
  21
  22   src = fetchFromGitHub {
  23     owner = "Myriad-Dreamin";
  24     repo = "tinymist";
  25     rev = "refs/tags/v${version}";
  26     hash = "sha256-z0JfHEG01q83iHAQA/Ke/DPhKQYwkWv9HRpeUdXmTxs=";
  27   };
  28
  29   cargoLock = {
  30     lockFile = ./Cargo.lock;
  31     outputHashes = {
  32       "typst-0.12.0" = "sha256-E2wSVHqY3SymCwKgbLsASJYaWfrbF8acH15B2STEBF8=";
  33       "typst-syntax-0.7.0" = "sha256-yrtOmlFAKOqAmhCP7n0HQCOQpU3DWyms5foCdUb9QTg=";
  34       "typstfmt_lib-0.2.7" = "sha256-LBYsTCjZ+U+lgd7Z3H1sBcWwseoHsuepPd66bWgfvhI=";
  35     };
  36   };
  37
  38   nativeBuildInputs = [ pkg-config ];
  39
  40   buildInputs =
  41     [
  42       libgit2
  43       openssl
  44       zlib
  45     ]
  46     ++ lib.optionals stdenv.hostPlatform.isDarwin [
  47       darwin.apple_sdk_11_0.frameworks.CoreFoundation
  48       darwin.apple_sdk_11_0.frameworks.CoreServices
  49       darwin.apple_sdk_11_0.frameworks.Security
  50       darwin.apple_sdk_11_0.frameworks.SystemConfiguration
  51     ];
  52
  53   checkFlags = [
  54     "--skip=e2e"
  55
  56     # Require internet access
  57     "--skip=docs::package::tests::cetz"
  58     "--skip=docs::package::tests::tidy"
  59     "--skip=docs::package::tests::touying"
  60   ];
  61
  62   nativeInstallCheckInputs = [
  63     versionCheckHook
  64   ];
  65   versionCheckProgramArg = [ "-V" ];
  66   doInstallCheck = true;
  67
  68   passthru = {
  69     updateScript = nix-update-script { };
  70     tests = {
  71       vscode-extension = vscode-extensions.myriad-dreamin.tinymist;
  72     };
  73   };
  74
  75   meta = {
  76     changelog = "https://github.com/Myriad-Dreamin/tinymist/blob/${src.rev}/CHANGELOG.md";
  77     description = "Tinymist is an integrated language service for Typst";
  78     homepage = "https://github.com/Myriad-Dreamin/tinymist";
  79     license = lib.licenses.asl20;
  80     mainProgram = "tinymist";
  81     maintainers = with lib.maintainers; [
  82       GaetanLepage
  83       lampros
  84     ];
  85   };
  86 }