pkgs/by-name/to/tomboy-ng/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   fpc,
   6   lazarus,
   7   autoPatchelfHook,
   8
   9   glib,
  10   cairo,
  11   pango,
  12   gtk2,
  13   gdk-pixbuf,
  14   at-spi2-atk,
  15   xorg,
  16   libnotify,
  17
  18   nix-update-script,
  19 }:
  20 stdenv.mkDerivation (finalAttrs: {
  21   pname = "tomboy-ng";
  22   version = "0.40";
  23
  24   src = fetchFromGitHub {
  25     owner = "tomboy-notes";
  26     repo = "tomboy-ng";
  27     rev = "v${finalAttrs.version}";
  28     hash = "sha256-QRv0LVZpRxW9c/cCcDsMSAYQ3zuYa39VJbcys5N+1x0=";
  29   };
  30   kcontrols = fetchFromGitHub {
  31     owner = "davidbannon";
  32     repo = "KControls";
  33     rev = "4b74f50599544aa05d76385c21795ca9026e9657";
  34     hash = "sha256-AHpcbt5v9Y/YG9MZ/zCLLH1Pfryv0zH8UFCgY/RqrdQ=";
  35     name = "kcontrols";
  36   };
  37
  38   nativeBuildInputs = [
  39     fpc
  40     lazarus
  41     autoPatchelfHook
  42   ];
  43
  44   buildInputs = [
  45     glib
  46     cairo
  47     pango
  48     gtk2
  49     gdk-pixbuf
  50     at-spi2-atk
  51     xorg.libX11
  52     libnotify
  53   ];
  54
  55   patches = [ ./simplify-build-script.patch ];
  56
  57   postPatch = "ln -s ${finalAttrs.kcontrols} kcontrols";
  58
  59   makeFlags = [ "PREFIX=${placeholder "out"}" ];
  60
  61   passthru.updateScript = nix-update-script {
  62     # Stable releases only
  63     extraArgs = [
  64       "--version-regex"
  65       "^v([0-9.]+)$"
  66     ];
  67   };
  68
  69   env = {
  70     COMPILER = lib.getExe' fpc "fpc";
  71     LAZ_DIR = "${lazarus}/share/lazarus";
  72   };
  73
  74   meta = {
  75     description = "Note taking app that works and synchronises between Linux, Windows and macOS";
  76     homepage = "https://github.com/tomboy-notes/tomboy-ng";
  77     license = with lib.licenses; [ mit ];
  78     maintainers = with lib.maintainers; [ pluiedev ];
  79     mainProgram = "tomboy-ng";
  80     platforms = lib.platforms.unix ++ lib.platforms.windows;
  81   };
  82 })