pkgs/by-name/uh/uhk-agent/package.nix

   1 { lib
   2 , stdenv
   3 , stdenvNoCC
   4 , fetchurl
   5 , appimageTools
   6 , electron
   7 , makeWrapper
   8 , asar
   9 , autoPatchelfHook
  10 , libusb1
  11 }:
  12
  13 let
  14   pname = "uhk-agent";
  15   version = "4.1.0";
  16
  17   src = fetchurl {
  18     url = "https://github.com/UltimateHackingKeyboard/agent/releases/download/v${version}/UHK.Agent-${version}-linux-x86_64.AppImage";
  19     name = "${pname}-${version}.AppImage";
  20     sha256 = "sha256-5VzUSuq+yc8HXSILMg24w/hbwasf4jq0H0wte9Mw+nY=";
  21   };
  22
  23   appimageContents = appimageTools.extract {
  24     inherit pname version src;
  25   };
  26 in
  27 stdenvNoCC.mkDerivation {
  28   inherit pname version src;
  29
  30   dontUnpack = true;
  31
  32   nativeBuildInputs = [
  33     asar
  34     makeWrapper
  35     autoPatchelfHook
  36   ];
  37
  38   buildInputs = [
  39     (lib.getLib stdenv.cc.cc)
  40     libusb1
  41   ];
  42
  43   autoPatchelfIgnoreMissingDeps = [
  44     "libc.musl-x86_64.so.1"
  45   ];
  46
  47   installPhase = ''
  48     runHook preInstall
  49
  50     mkdir -p "$out"/{opt,share/applications}
  51
  52     cp -r --no-preserve=mode "${appimageContents}/resources"        "$out/opt/${pname}"
  53     cp -r --no-preserve=mode "${appimageContents}/usr/share/icons"  "$out/share/icons"
  54     cp -r --no-preserve=mode "${appimageContents}/${pname}.desktop" "$out/share/applications/${pname}.desktop"
  55
  56     substituteInPlace "$out/share/applications/${pname}.desktop" \
  57       --replace "Exec=AppRun" "Exec=${pname}"
  58
  59     asar extract "$out/opt/${pname}/app.asar" "$out/opt/${pname}/app.asar.unpacked"
  60     rm           "$out/opt/${pname}/app.asar"
  61
  62     makeWrapper "${electron}/bin/electron" "$out/bin/${pname}" \
  63       --add-flags "$out/opt/${pname}/app.asar.unpacked" \
  64       --add-flags "\''${NIXOS_OZONE_WL:+\''${WAYLAND_DISPLAY:+--ozone-platform-hint=auto --enable-features=WaylandWindowDecorations}}" \
  65       --set-default ELECTRON_IS_DEV 0 \
  66       --inherit-argv0
  67
  68     runHook postInstall
  69   '';
  70
  71   meta = with lib; {
  72     description = "Agent is the configuration application of the Ultimate Hacking Keyboard";
  73     homepage = "https://github.com/UltimateHackingKeyboard/agent";
  74     license = licenses.unfreeRedistributable;
  75     maintainers = with maintainers; [ ngiger nickcao ];
  76     platforms = [ "x86_64-linux" ];
  77   };
  78 }