pkgs/by-name/vi/viper4linux/package.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , gst_all_1
   5 , libviperfx
   6 , makeWrapper
   7 }:
   8 let
   9   gstPluginPath = lib.makeSearchPathOutput "lib" "lib/gstreamer-1.0" (with gst_all_1; [ gstreamer gst-plugins-viperfx gst-plugins-base gst-plugins-good ]);
  10 in
  11 stdenv.mkDerivation rec {
  12   pname = "viper4linux";
  13   version = "unstable-2022-03-13";
  14
  15   src = fetchFromGitHub {
  16     owner = "Audio4Linux";
  17     repo = "Viper4Linux";
  18     rev = "5da25644824f88cf0db24378d2c84770ba4f6816";
  19     sha256 = "sha256-CJNVr/1ehJzX45mxunXcRAypBBGEBdswOzAVG2H+ayg=";
  20   };
  21
  22   nativeBuildInputs = [ makeWrapper ];
  23
  24   buildInputs = [
  25     gst_all_1.gstreamer
  26     gst_all_1.gst-plugins-base
  27     gst_all_1.gst-plugins-good
  28     gst_all_1.gst-plugins-viperfx
  29     libviperfx
  30   ];
  31
  32   dontBuild = true;
  33
  34   postPatch = ''
  35     substituteInPlace viper --replace "/etc/viper4linux" "$out/etc/viper4linux"
  36   '';
  37
  38   installPhase = ''
  39     runHook preInstall
  40     install -D viper -t $out/bin
  41     mkdir -p $out/etc/viper4linux
  42     cp -r viper4linux/* $out/etc/viper4linux
  43     runHook postInstall
  44   '';
  45
  46   postFixup = ''
  47     wrapProgram "$out/bin/viper" \
  48       --prefix PATH : $out/bin:${lib.makeBinPath [ gst_all_1.gstreamer ]} \
  49       --prefix GST_PLUGIN_SYSTEM_PATH_1_0 : ${gstPluginPath} \
  50       --prefix LD_LIBRARY_PATH : ${lib.makeLibraryPath [ libviperfx ]}
  51   '';
  52
  53   meta = with lib; {
  54     description = "Adaptive Digital Sound Processor";
  55     homepage = "https://github.com/Audio4Linux/Viper4Linux";
  56     license = licenses.gpl3Plus;
  57     platforms = [ "x86_64-linux" ];
  58     maintainers = with maintainers; [ rewine ];
  59   };
  60 }