pkgs/by-name/wo/wordbook/package.nix

   1 { lib
   2 , fetchFromGitHub
   3 , python3
   4 , meson
   5 , ninja
   6 , pkg-config
   7 , glib
   8 , gtk4
   9 , libadwaita
  10 , librsvg
  11 , espeak-ng
  12 , gobject-introspection
  13 , wrapGAppsHook4
  14 , appstream-glib
  15 , desktop-file-utils
  16 }:
  17
  18 python3.pkgs.buildPythonApplication rec {
  19   pname = "wordbook";
  20   version = "unstable-2022-11-02";
  21   format = "other";
  22
  23   src = fetchFromGitHub {
  24     owner = "fushinari";
  25     repo = "Wordbook";
  26     rev = "2d79e9e9ef21ba4b54d0b46c764a1481a06f0f1b";
  27     hash = "sha256-ktusZEQ7m8P0kiH09r3XC6q9bQCWVCn543IMLKmULDo=";
  28   };
  29
  30   nativeBuildInputs = [
  31     meson
  32     ninja
  33     pkg-config
  34     wrapGAppsHook4
  35     appstream-glib
  36     desktop-file-utils
  37     gobject-introspection
  38   ];
  39
  40   buildInputs = [
  41     glib
  42     gtk4
  43     librsvg
  44     libadwaita
  45   ];
  46
  47   propagatedBuildInputs = with python3.pkgs; [
  48     pygobject3
  49     wn
  50   ];
  51
  52   # prevent double wrapping
  53   dontWrapGApps = true;
  54
  55   preFixup = ''
  56     makeWrapperArgs+=(
  57       --prefix PATH ":" "${lib.makeBinPath [ espeak-ng ]}"
  58       "''${gappsWrapperArgs[@]}"
  59     )
  60   '';
  61
  62   meta = with lib; {
  63     description = "Offline English-English dictionary application built for GNOME";
  64     mainProgram = "wordbook";
  65     homepage = "https://github.com/fushinari/Wordbook";
  66     license = licenses.gpl3Plus;
  67     platforms = platforms.linux;
  68     maintainers = with maintainers; [ zendo ];
  69   };
  70 }