pkgs/by-name/yt/ytui-music/package.nix

   1 { lib
   2 , rustPlatform
   3 , fetchFromGitHub
   4 , pkg-config
   5 , openssl
   6 , sqlite
   7 , stdenv
   8 , darwin
   9 , mpv
  10 , youtube-dl
  11 , makeBinaryWrapper
  12 }:
  13
  14 rustPlatform.buildRustPackage rec {
  15   pname = "ytui-music";
  16   version = "2.0.0-rc1";
  17
  18   src = fetchFromGitHub {
  19     owner = "sudipghimire533";
  20     repo = "ytui-music";
  21     rev = "v${version}";
  22     hash = "sha256-f/23PVk4bpUCvcQ25iNI/UVXqiPBzPKWq6OohVF41p8=";
  23   };
  24
  25   cargoHash = "sha256-766Wev2/R/9LLlWWxOPl6y4CBRUU4hUrTDlVVuoJ8C8=";
  26
  27   checkFlags = [
  28     "--skip=tests::display_config_path"
  29     "--skip=tests::inspect_server_list"
  30   ];
  31
  32   nativeBuildInputs = [
  33     pkg-config
  34     makeBinaryWrapper
  35   ];
  36
  37   buildInputs = [
  38     openssl
  39     sqlite
  40     mpv
  41   ] ++ lib.optionals stdenv.hostPlatform.isDarwin [
  42     darwin.apple_sdk.frameworks.CoreFoundation
  43     darwin.apple_sdk.frameworks.Security
  44   ];
  45
  46   postInstall = ''
  47     wrapProgram $out/bin/ytui_music \
  48       --prefix PATH : ${lib.makeBinPath [ youtube-dl ]}
  49   '';
  50
  51   doInstallCheck = true;
  52
  53   installCheckPhase = ''
  54     runHook preInstallCheck
  55
  56     $out/bin/ytui_music help
  57
  58     runHook postInstallCheck
  59   '';
  60
  61   meta = with lib; {
  62     description = "Youtube client in terminal for music";
  63     homepage = "https://github.com/sudipghimire533/ytui-music";
  64     license = licenses.gpl2Only;
  65     maintainers = with maintainers; [ kashw2 ];
  66     mainProgram = "ytui_music";
  67   };
  68 }