pkgs/by-name/ze/zerotierone/package.nix

   1 { lib
   2 , stdenv
   3 , rustPlatform
   4 , fetchFromGitHub
   5 , buildPackages
   6 , cargo
   7 , lzo
   8 , openssl
   9 , pkg-config
  10 , ronn
  11 , rustc
  12 , zlib
  13 , libiconv
  14 , darwin
  15 , fetchpatch
  16 }:
  17
  18 let
  19   pname = "zerotierone";
  20   version = "1.14.0";
  21
  22   src = fetchFromGitHub {
  23     owner = "zerotier";
  24     repo = "ZeroTierOne";
  25     rev = version;
  26     hash = "sha256-YWcqALUB3ZEukL4er2FKcyNdEbuaf//QU5hRbKAfxDA=";
  27   };
  28
  29 in stdenv.mkDerivation {
  30   inherit pname version src;
  31
  32   cargoDeps = rustPlatform.importCargoLock {
  33     lockFile = ./Cargo.lock;
  34     outputHashes = {
  35       "jwt-0.16.0" = "sha256-P5aJnNlcLe9sBtXZzfqHdRvxNfm6DPBcfcKOVeLZxcM=";
  36       "rustfsm-0.1.0" = "sha256-q7J9QgN67iuoNhQC8SDVzUkjCNRXGiNCkE8OsQc5+oI=";
  37     };
  38   };
  39   patches = [
  40     # https://github.com/zerotier/ZeroTierOne/pull/2314
  41     (fetchpatch {
  42       url = "https://github.com/zerotier/ZeroTierOne/commit/f9c6ee0181acb1b77605d9a4e4106ac79aaacca3.patch";
  43       hash = "sha256-zw7KmaxiCH99Y0wQtOQM4u0ruxiePhvv/birxMQioJU=";
  44     })
  45     ./0001-darwin-disable-link-time-optimization.patch
  46   ];
  47   postPatch = ''
  48     cp ${./Cargo.lock} Cargo.lock
  49     cp ${./Cargo.lock} rustybits/Cargo.lock
  50   '';
  51
  52
  53   preConfigure = ''
  54     cmp ./Cargo.lock ./rustybits/Cargo.lock || {
  55       echo 1>&2 "Please make sure that the derivation's Cargo.lock is identical to ./rustybits/Cargo.lock!"
  56       exit 1
  57     }
  58
  59     patchShebangs ./doc/build.sh
  60     substituteInPlace ./doc/build.sh \
  61       --replace '/usr/bin/ronn' '${buildPackages.ronn}/bin/ronn' \
  62
  63     substituteInPlace ./make-linux.mk \
  64       --replace '-march=armv6zk' "" \
  65       --replace '-mcpu=arm1176jzf-s' ""
  66   '';
  67
  68   nativeBuildInputs = [
  69     pkg-config
  70     ronn
  71     rustPlatform.cargoSetupHook
  72     cargo
  73     rustc
  74   ];
  75
  76   buildInputs = [
  77     lzo
  78     openssl
  79     zlib
  80   ] ++ lib.optionals stdenv.hostPlatform.isDarwin [
  81     libiconv
  82     darwin.apple_sdk.frameworks.SystemConfiguration
  83     darwin.apple_sdk.frameworks.CoreServices
  84   ];
  85
  86   enableParallelBuilding = true;
  87
  88   # Ensure Rust compiles for the right target
  89   env.CARGO_BUILD_TARGET = stdenv.hostPlatform.rust.rustcTarget;
  90
  91   preBuild = if stdenv.hostPlatform.isDarwin then ''
  92     makeFlagsArray+=("ARCH_FLAGS=") # disable multi-arch build
  93     if ! grep -q MACOS_VERSION_MIN=10.13 make-mac.mk; then
  94       echo "You may need to update MACOSX_DEPLOYMENT_TARGET to match the value in make-mac.mk"
  95       exit 1
  96     fi
  97     (cd rustybits && MACOSX_DEPLOYMENT_TARGET=10.13 cargo build -p zeroidc --release)
  98
  99     cp \
 100       ./rustybits/target/${stdenv.hostPlatform.rust.rustcTarget}/release/libzeroidc.a \
 101       ./rustybits/target
 102
 103     # zerotier uses the "FORCE" target as a phony target to force rebuilds.
 104     # We don't want to rebuild libzeroidc.a as we build want to build this library ourself for a single architecture
 105     touch FORCE
 106   '' else ''
 107     # Cargo won't compile to target/release but to target/<RUST_TARGET>/release when a target is
 108     # explicitly defined. The build-system however expects target/release. Hence we just symlink from
 109     # the latter to the former.
 110     mkdir -p rustybits/target/release
 111     ln -rs \
 112       ./rustybits/target/${stdenv.hostPlatform.rust.rustcTarget}/release/libzeroidc.a \
 113       ./rustybits/target/release/
 114   '';
 115
 116   buildFlags = [ "all" "selftest" ];
 117
 118   doCheck = stdenv.buildPlatform.canExecute stdenv.hostPlatform;
 119   checkPhase = ''
 120     runHook preCheck
 121     ./zerotier-selftest
 122     runHook postCheck
 123   '';
 124
 125   installFlags = [
 126     # only linux has an install target, we borrow this for macOS as well
 127     "-f" "make-linux.mk"
 128     "DESTDIR=$$out/upstream"
 129   ];
 130
 131   postInstall = ''
 132     mv $out/upstream/usr/sbin $out/bin
 133
 134     mkdir -p $man/share
 135     mv $out/upstream/usr/share/man $man/share/man
 136
 137     rm -rf $out/upstream
 138   '';
 139
 140   outputs = [ "out" "man" ];
 141
 142   passthru.updateScript = ./update.sh;
 143
 144   meta = with lib; {
 145     description = "Create flat virtual Ethernet networks of almost unlimited size";
 146     homepage = "https://www.zerotier.com";
 147     license = licenses.bsl11;
 148     maintainers = with maintainers; [
 149       sjmackenzie zimbatm ehmry obadz danielfullmer
 150       mic92 # also can test darwin
 151     ];
 152     platforms = platforms.unix;
 153   };
 154 }