pkgs/by-name/al/alttpr-opentracker/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   buildDotnetModule,
   5   fetchFromGitHub,
   6   autoPatchelfHook,
   7   wrapGAppsHook3,
   8   dotnetCorePackages,
   9   fontconfig,
  10   gtk3,
  11   icu,
  12   libkrb5,
  13   libunwind,
  14   openssl,
  15   xinput,
  16   xorg,
  17 }:
  18 buildDotnetModule rec {
  19   pname = "opentracker";
  20   version = "1.8.5";
  21
  22   src = fetchFromGitHub {
  23     owner = "trippsc2";
  24     repo = pname;
  25     rev = "refs/tags/${version}";
  26     hash = "sha512-nWkPgVYdnBJibyJRdLPe3O3RioDPbzumSritRejmr4CeiPb7aUTON7HjivcV/GKor1guEYu+TJ+QxYrqO/eppg==";
  27   };
  28
  29   patches = [./remove-project.patch];
  30
  31   dotnet-runtime = dotnetCorePackages.runtime_6_0;
  32
  33   nugetDeps = ./deps.nix;
  34
  35   projectFile = "OpenTracker.sln";
  36   executables = ["OpenTracker"];
  37
  38   doCheck = true;
  39   disabledTests = [
  40     "OpenTracker.UnitTests.Models.Nodes.Factories.SLightWorldConnectionFactoryTests.GetNodeConnections_ShouldReturnExpectedValue"
  41     "OpenTracker.UnitTests.Models.Sections.Factories.ItemSectionFactoryTests.GetItemSection_ShouldReturnExpected"
  42   ];
  43
  44   nativeBuildInputs = [
  45     autoPatchelfHook
  46     wrapGAppsHook3
  47   ];
  48
  49   buildInputs = [
  50     (lib.getLib stdenv.cc.cc)
  51     fontconfig
  52     gtk3
  53     icu
  54     libkrb5
  55     libunwind
  56     openssl
  57   ];
  58
  59   runtimeDeps =
  60     [
  61       gtk3
  62       openssl
  63       xinput
  64     ]
  65     ++ (with xorg; [
  66       libICE
  67       libSM
  68       libX11
  69       libXi
  70     ]);
  71
  72   autoPatchelfIgnoreMissingDeps = [
  73     "libc.musl-x86_64.so.1"
  74     "libintl.so.8"
  75   ];
  76
  77   meta = with lib; {
  78     description = "Tracking application for A Link to the Past Randomizer";
  79     homepage = "https://github.com/trippsc2/OpenTracker";
  80     sourceProvenance = with sourceTypes; [
  81       fromSource
  82       # deps
  83       binaryBytecode
  84       binaryNativeCode
  85     ];
  86     license = licenses.mit;
  87     maintainers = [ ];
  88     mainProgram = "OpenTracker";
  89     platforms = ["x86_64-linux"];
  90   };
  91 }