pkgs/by-name/ke/keyutils/package.nix

   1 { lib, stdenv, fetchurl }:
   2
   3 # Note: this package is used for bootstrapping fetchurl, and thus
   4 # cannot use fetchpatch! All mutable patches (generated by GitHub or
   5 # cgit) that are needed here should be included directly in Nixpkgs as
   6 # files.
   7
   8 stdenv.mkDerivation rec {
   9   pname = "keyutils";
  10   version = "1.6.3";
  11
  12   src = fetchurl {
  13     url = "https://git.kernel.org/pub/scm/linux/kernel/git/dhowells/keyutils.git/snapshot/${pname}-${version}.tar.gz";
  14     sha256 = "sha256-ph1XBhNq5MBb1I+GGGvP29iN2L1RB+Phlckkz8Gzm7Q=";
  15   };
  16
  17   patches = [
  18     ./conf-symlink.patch
  19     # This patch solves a duplicate symbol error when building with a clang stdenv
  20     # Before removing this patch, please ensure the package still builds by running eg.
  21     # nix-build -E 'with import ./. {}; pkgs.keyutils.override { stdenv = pkgs.clangStdenv; }'
  22     ./0001-Remove-unused-function-after_eq.patch
  23
  24     ./pkg-config-static.patch
  25
  26     # Fix build for s390-linux, where size_t is different from ptrdiff_t.
  27     (fetchurl {
  28       url = "https://lore.kernel.org/keyrings/20230301134250.301819-1-hi@alyssa.is/raw";
  29       sha256 = "1cbgwxq28fw5ldh38ngcs7xiqvpnmrw0hw9zzhbhb1hdxkavrc1s";
  30     })
  31   ];
  32
  33   makeFlags = lib.optionals stdenv.hostPlatform.isStatic "NO_SOLIB=1";
  34
  35   outputs = [ "out" "lib" "dev" "man" ];
  36
  37   postPatch = ''
  38     # https://github.com/archlinux/svntogit-packages/blob/packages/keyutils/trunk/reproducible.patch
  39     substituteInPlace Makefile \
  40       --replace \
  41         'VCPPFLAGS      := -DPKGBUILD="\"$(shell date -u +%F)\""' \
  42         'VCPPFLAGS      := -DPKGBUILD="\"$(date -ud "@$SOURCE_DATE_EPOCH" +%F)\""'
  43   '';
  44
  45   enableParallelBuilding = true;
  46
  47   installFlags = [
  48     "ETCDIR=$(out)/etc"
  49     "BINDIR=$(out)/bin"
  50     "SBINDIR=$(out)/sbin"
  51     "SHAREDIR=$(out)/share/keyutils"
  52     "MANDIR=$(out)/share/man"
  53     "INCLUDEDIR=$(dev)/include"
  54     "LIBDIR=$(lib)/lib"
  55     "USRLIBDIR=$(lib)/lib"
  56   ];
  57
  58   meta = with lib; {
  59     homepage = "https://people.redhat.com/dhowells/keyutils/";
  60     description = "Tools used to control the Linux kernel key management system";
  61     license = licenses.gpl2Plus;
  62     platforms = platforms.linux;
  63   };
  64 }