pkgs/by-name/li/libelf/package.nix

   1 { lib, stdenv
   2 , fetchurl, autoreconfHook, gettext, freebsd, netbsd
   3 }:
   4
   5 stdenv.mkDerivation rec {
   6   pname = "libelf";
   7   version = "0.8.13";
   8
   9   src = fetchurl {
  10     url = "https://fossies.org/linux/misc/old/${pname}-${version}.tar.gz";
  11     sha256 = "0vf7s9dwk2xkmhb79aigqm0x0yfbw1j0b9ksm51207qwr179n6jr";
  12   };
  13
  14   patches = [
  15     ./dont-hardcode-ar.patch
  16     # Fix warnings from preprocessor instructions.
  17     # https://github.com/NixOS/nixpkgs/issues/59929
  18     ./preprocessor-warnings.patch
  19     # `configure` defines a test `main` with an implicit `int` return, which clang 16 disallows.
  20     ./fix-configure-main.patch
  21   ];
  22
  23   enableParallelBuilding = true;
  24   # Lacks dependencies:
  25   #   mkdir ...-libelf-0.8.13/lib
  26   #   mkdir ...-libelf-0.8.13/lib
  27   # mkdir: cannot create directory '...-libelf-0.8.13/lib': File exists
  28   enableParallelInstalling = false;
  29
  30   doCheck = true;
  31
  32   preConfigure = if !stdenv.hostPlatform.useAndroidPrebuilt then null else ''
  33     sed -i 's|DISTSUBDIRS = lib po|DISTSUBDIRS = lib|g' Makefile.in
  34     sed -i 's|SUBDIRS = lib @POSUB@|SUBDIRS = lib|g' Makefile.in
  35   '';
  36
  37   configureFlags = []
  38        # Configure check for dynamic lib support is broken, see
  39        # http://lists.uclibc.org/pipermail/uclibc-cvs/2005-August/019383.html
  40     ++ lib.optional (stdenv.hostPlatform != stdenv.buildPlatform) "mr_cv_target_elf=yes"
  41        # Libelf's custom NLS macros fail to determine the catalog file extension
  42        # on Darwin, so disable NLS for now.
  43     ++ lib.optional stdenv.hostPlatform.isDarwin "--disable-nls";
  44
  45   strictDeps = true;
  46   nativeBuildInputs =
  47     (if stdenv.hostPlatform.isFreeBSD then [ freebsd.gencat ]
  48      else if stdenv.hostPlatform.isNetBSD then [ netbsd.gencat ]
  49      else [ gettext ])
  50        # The provided `configure` script fails on clang 16 because some tests have a `main`
  51        # returning an implicit `int`, which clang 16 treats as an error. Running `autoreconf` fixes
  52        # the test and allows `configure` to detect clang properly.
  53     ++ [ autoreconfHook ];
  54
  55   meta = {
  56     description = "ELF object file access library";
  57
  58     homepage = "https://github.com/Distrotech/libelf";
  59
  60     license = lib.licenses.lgpl2Plus;
  61
  62     platforms = lib.platforms.all;
  63     maintainers = [ ];
  64   };
  65 }