pkgs/by-name/wo/wob/package.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , inih
   5 , meson
   6 , ninja
   7 , pkg-config
   8 , cmocka
   9 , scdoc
  10 , wayland-scanner
  11 , wayland
  12 , wayland-protocols
  13 , libseccomp
  14 }:
  15
  16 stdenv.mkDerivation rec {
  17   pname = "wob";
  18   version = "0.15.1";
  19
  20   src = fetchFromGitHub {
  21     owner = "francma";
  22     repo = pname;
  23     rev = version;
  24     sha256 = "sha256-9LFAEo17w861ldMJU+t1oLAKoM6gJc4Em4tSwQDXbKU=";
  25   };
  26
  27   strictDeps = true;
  28   depsBuildBuild = [
  29     pkg-config
  30   ];
  31   nativeBuildInputs = [ meson ninja pkg-config scdoc wayland-scanner ];
  32   buildInputs = [ cmocka inih wayland wayland-protocols ]
  33     ++ lib.optional stdenv.hostPlatform.isLinux libseccomp;
  34
  35   mesonFlags = lib.optional stdenv.hostPlatform.isLinux "-Dseccomp=enabled";
  36
  37   meta = with lib; {
  38     inherit (src.meta) homepage;
  39     description = "Lightweight overlay bar for Wayland";
  40     longDescription = ''
  41       A lightweight overlay volume/backlight/progress/anything bar for Wayland,
  42       inspired by xob.
  43     '';
  44     changelog = "https://github.com/francma/wob/releases/tag/${version}";
  45     license = licenses.isc;
  46     maintainers = with maintainers; [ primeos ];
  47     platforms = platforms.linux;
  48     mainProgram = "wob";
  49   };
  50 }