pkgs/by-name/ap/apfsprogs/package.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , nixosTests
   5 }:
   6
   7 stdenv.mkDerivation (finalAttrs: {
   8   pname = "apfsprogs";
   9   version = "unstable-2023-11-30";
  10
  11   src = fetchFromGitHub {
  12     owner = "linux-apfs";
  13     repo = "apfsprogs";
  14     rev = "990163894d871f51ba102a75aed384a275c5991b";
  15     hash = "sha256-yCShZ+ALzSe/svErt9/i1JyyEvbIeABGPbpS4lVil0A=";
  16   };
  17
  18   postPatch = let
  19     shortRev = builtins.substring 0 9 finalAttrs.src.rev;
  20   in ''
  21     substituteInPlace \
  22       apfs-snap/Makefile apfsck/Makefile mkapfs/Makefile \
  23       --replace \
  24         '$(shell git describe --always HEAD | tail -c 9)' \
  25         '${shortRev}'
  26   '';
  27
  28   buildPhase = ''
  29     runHook preBuild
  30     make -C apfs-snap $makeFlags
  31     make -C apfsck $makeFlags
  32     make -C mkapfs $makeFlags
  33     runHook postBuild
  34   '';
  35
  36   installPhase = ''
  37     runHook preInstall
  38     make -C apfs-snap install DESTDIR="$out" $installFlags
  39     make -C apfsck install DESTDIR="$out" $installFlags
  40     make -C mkapfs install DESTDIR="$out" $installFlags
  41     runHook postInstall
  42   '';
  43
  44   passthru.tests = {
  45     apfs = nixosTests.apfs;
  46   };
  47
  48   strictDeps = true;
  49
  50   meta = with lib; {
  51     description = "Experimental APFS tools for linux";
  52     homepage = "https://github.com/linux-apfs/apfsprogs";
  53     license = licenses.gpl2Only;
  54     platforms = platforms.linux;
  55     maintainers = with maintainers; [ Luflosi ];
  56   };
  57 })