pkgs/by-name/ca/catppuccin-plymouth/package.nix

   1 {
   2   stdenvNoCC,
   3   lib,
   4   fetchFromGitHub,
   5   unstableGitUpdater,
   6   variant ? "macchiato",
   7 }:
   8
   9 let
  10   pname = "catppuccin-plymouth";
  11   validVariants = [
  12     "latte"
  13     "frappe"
  14     "macchiato"
  15     "mocha"
  16   ];
  17 in
  18 lib.checkListOfEnum "${pname}: color variant" validVariants [ variant ]
  19
  20   stdenvNoCC.mkDerivation
  21   (finalAttrs: {
  22     inherit pname;
  23     version = "0-unstable-2024-05-28";
  24
  25     src = fetchFromGitHub {
  26       owner = "catppuccin";
  27       repo = "plymouth";
  28       rev = "e13c348a0f47772303b2da1e9396027d8cda160d";
  29       hash = "sha256-6DliqhRncvdPuKzL9LJec3PJWmK/jo9BrrML7g6YcH0=";
  30     };
  31
  32     sourceRoot = "${finalAttrs.src.name}/themes/catppuccin-${variant}";
  33
  34     installPhase = ''
  35       runHook preInstall
  36
  37       sed -i 's:\(^ImageDir=\)/usr:\1'"$out"':' catppuccin-${variant}.plymouth
  38       mkdir -p $out/share/plymouth/themes/catppuccin-${variant}
  39       cp * $out/share/plymouth/themes/catppuccin-${variant}
  40
  41       runHook postInstall
  42     '';
  43
  44     passthru.updateScript = unstableGitUpdater { };
  45
  46     meta = {
  47       description = "Soothing pastel theme for Plymouth";
  48       homepage = "https://github.com/catppuccin/plymouth";
  49       license = lib.licenses.mit;
  50       platforms = lib.platforms.linux;
  51       maintainers = with lib.maintainers; [
  52         johnrtitor
  53         spectre256
  54       ];
  55     };
  56   })