pkgs/by-name/ce/centerpiece/package.nix

   1 { lib
   2 , stdenv
   3 , pkg-config
   4 , dbus
   5 , vulkan-loader
   6 , libGL
   7 , fetchFromGitHub
   8 , rustPlatform
   9 , libxkbcommon
  10 , wayland
  11 , enableX11 ? true, xorg
  12 }:
  13
  14 rustPlatform.buildRustPackage rec {
  15   pname = "centerpiece";
  16   version = "1.1.0";
  17
  18   src = fetchFromGitHub {
  19     owner = "friedow";
  20     repo = "centerpiece";
  21     rev = "v${version}";
  22     hash = "sha256-1sKUGTBS9aTCQPuhkwv9fZ8F3N6yn98927fpp1e4fBU=";
  23   };
  24
  25   cargoHash = "sha256-b7gI6Z5fiOA/Q2BbsmmGrKHgMzbICKPeK2i6YjlLnDo=";
  26
  27   nativeBuildInputs = [ pkg-config ];
  28   buildInputs = [
  29     dbus
  30     libGL
  31     libxkbcommon
  32     vulkan-loader
  33     wayland
  34   ] ++ lib.optionals enableX11 (with xorg; [
  35     libX11
  36     libXcursor
  37     libXi
  38     libXrandr
  39   ]);
  40
  41   postFixup = lib.optional stdenv.isLinux ''
  42     rpath=$(patchelf --print-rpath $out/bin/centerpiece)
  43     patchelf --set-rpath "$rpath:${
  44       lib.makeLibraryPath [
  45         libGL
  46         libxkbcommon
  47         vulkan-loader
  48         wayland
  49       ]
  50     }" $out/bin/centerpiece
  51   '';
  52
  53   meta = with lib; {
  54     homepage = "https://github.com/friedow/centerpiece";
  55     description = "Your trusty omnibox search";
  56     license = licenses.mit;
  57     maintainers = with maintainers; [ a-kenji friedow ];
  58     platforms = platforms.linux;
  59     mainProgram = "centerpiece";
  60   };
  61 }