pkgs/by-name/et/etlegacy-assets/package.nix

   1 { lib
   2 , stdenv
   3 , fetchurl
   4 }:
   5
   6 stdenv.mkDerivation {
   7   pname = "etlegacy-assets";
   8   version = "2.82.0";
   9
  10   srcs = let
  11     fetchAsset = { asset, hash }: fetchurl {
  12       url = "https://mirror.etlegacy.com/etmain/${asset}";
  13       inherit hash;
  14     };
  15   in [
  16     (fetchAsset {
  17       asset = "pak0.pk3";
  18       hash = "sha256-cSlmsg4GUj/oFBlRZQDkmchrK0/sgjhW3b0zP8s9JuU=";
  19     })
  20     (fetchAsset {
  21       asset = "pak1.pk3";
  22       hash = "sha256-VhD9dJAkQFtEJafOY5flgYe5QdIgku8R1IRLQn31Pl0=";
  23     })
  24     (fetchAsset {
  25       asset = "pak2.pk3";
  26       hash = "sha256-pIq3SaGhKrTZE3KGsfI9ZCwp2lmEWyuvyPZOBSzwbz4=";
  27     })
  28   ];
  29
  30   sourceRoot = ".";
  31   unpackCmd = "cp -r $curSrc \${curSrc##*-}";
  32
  33   installPhase = ''
  34     runHook preInstall
  35     mkdir -p $out/lib/etlegacy/etmain
  36     cp -r . $out/lib/etlegacy/etmain/
  37     runHook postInstall
  38   '';
  39
  40   meta = {
  41     description = "ET: Legacy assets only";
  42     homepage = "https://etlegacy.com";
  43     license = with lib.licenses; [ cc-by-nc-sa-30 ];
  44     longDescription = ''
  45       ET: Legacy, an open source project fully compatible client and server
  46       for the popular online FPS game Wolfenstein: Enemy Territory - whose
  47       gameplay is still considered unmatched by many, despite its great age.
  48     '';
  49     maintainers = with lib.maintainers; [ drupol ];
  50     platforms = lib.platforms.linux;
  51   };
  52 }