pkgs/by-name/fl/fluxcd/package.nix

   1 {
   2   buildGoModule,
   3   fetchFromGitHub,
   4   fetchzip,
   5   installShellFiles,
   6   lib,
   7   stdenv,
   8 }:
   9
  10 let
  11   version = "2.3.0";
  12   sha256 = "sha256-ZQs1rWI31qDo/BgjrmiNnEdR2OL8bUHVz+j5VceEp2k=";
  13   manifestsSha256 = "sha256-PdhR+UDquIJWtpSymtT6V7qO5fVJOkFz6RGzAx7xeb4=";
  14
  15   manifests = fetchzip {
  16     url = "https://github.com/fluxcd/flux2/releases/download/v${version}/manifests.tar.gz";
  17     hash = manifestsSha256;
  18     stripRoot = false;
  19   };
  20 in
  21
  22 buildGoModule rec {
  23   pname = "fluxcd";
  24   inherit version;
  25
  26   src = fetchFromGitHub {
  27     owner = "fluxcd";
  28     repo = "flux2";
  29     rev = "v${version}";
  30     hash = sha256;
  31   };
  32
  33   vendorHash = "sha256-0YH3pgFrsnh5jIsZpj/sIgfiOCTtIlPltMS5mdGz1eM=";
  34
  35   postUnpack = ''
  36     cp -r ${manifests} source/cmd/flux/manifests
  37
  38     # disable tests that require network access
  39     rm source/cmd/flux/create_secret_git_test.go
  40   '';
  41
  42   ldflags = [
  43     "-s"
  44     "-w"
  45     "-X main.VERSION=${version}"
  46   ];
  47
  48   subPackages = [ "cmd/flux" ];
  49
  50   # Required to workaround test error:
  51   #   panic: mkdir /homeless-shelter: permission denied
  52   HOME = "$TMPDIR";
  53
  54   nativeBuildInputs = [ installShellFiles ];
  55
  56   doInstallCheck = true;
  57   installCheckPhase = ''
  58     $out/bin/flux --version | grep ${version} > /dev/null
  59   '';
  60
  61   postInstall = lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
  62     for shell in bash fish zsh; do
  63       installShellCompletion --cmd flux \
  64         --$shell <($out/bin/flux completion $shell)
  65     done
  66   '';
  67
  68   passthru.updateScript = ./update.sh;
  69
  70   meta = {
  71     changelog = "https://github.com/fluxcd/flux2/releases/tag/v${version}";
  72     description = "Open and extensible continuous delivery solution for Kubernetes";
  73     downloadPage = "https://github.com/fluxcd/flux2/";
  74     longDescription = ''
  75       Flux is a tool for keeping Kubernetes clusters in sync
  76       with sources of configuration (like Git repositories), and automating
  77       updates to configuration when there is new code to deploy.
  78     '';
  79     homepage = "https://fluxcd.io";
  80     license = lib.licenses.asl20;
  81     maintainers = with lib.maintainers; [
  82       bryanasdev000
  83       jlesquembre
  84       superherointj
  85     ];
  86     mainProgram = "flux";
  87   };
  88 }