pkgs/by-name/op/openjump/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchurl,
   5   unzip,
   6   makeBinaryWrapper,
   7   coreutils,
   8   gawk,
   9   which,
  10   gnugrep,
  11   findutils,
  12   jre,
  13 }:
  14
  15 stdenv.mkDerivation (finalAttrs: {
  16   pname = "openjump";
  17   version = "2.2.1";
  18   revision = "r5222%5B94156e5%5D";
  19
  20   src = fetchurl {
  21     url = "mirror://sourceforge/jump-pilot/OpenJUMP/${finalAttrs.version}/OpenJUMP-Portable-${finalAttrs.version}-${finalAttrs.revision}-PLUS.zip";
  22     hash = "sha256-+/AMmD6NDPy+2Gq1Ji5i/QWGU7FOsU+kKsWoNXcx/VI=";
  23   };
  24
  25   # TODO: build from source
  26   unpackPhase = ''
  27     runHook preUnpack
  28     mkdir -p $out/opt
  29     unzip $src -d $out/opt
  30     runHook postUnpack
  31   '';
  32
  33   nativeBuildInputs = [
  34     makeBinaryWrapper
  35     unzip
  36   ];
  37
  38   installPhase = ''
  39     runHook preInstall
  40     dir=$(echo $out/opt/OpenJUMP-*)
  41
  42     chmod +x "$dir/bin/oj_linux.sh"
  43     makeWrapper "$dir/bin/oj_linux.sh" $out/bin/OpenJump \
  44       --set JAVA_HOME ${jre} \
  45       --set PATH ${
  46         lib.makeBinPath [
  47           coreutils
  48           gawk
  49           which
  50           gnugrep
  51           findutils
  52         ]
  53       }
  54     runHook postInstall
  55   '';
  56
  57   meta = {
  58     description = "Open source Geographic Information System (GIS) written in the Java programming language";
  59     homepage = "http://www.openjump.org/";
  60     license = lib.licenses.gpl2;
  61     mainProgram = "OpenJump";
  62     maintainers = lib.teams.geospatial.members ++ [ lib.maintainers.marcweber ];
  63     platforms = jre.meta.platforms;
  64     sourceProvenance = [ lib.sourceTypes.binaryBytecode ];
  65   };
  66 })