pkgs/by-name/po/powerpipe/package.nix

   1 {
   2   buildGoModule,
   3   fetchFromGitHub,
   4   installShellFiles,
   5   lib,
   6   makeWrapper,
   7   nix-update-script,
   8   powerpipe,
   9   testers,
  10 }:
  11
  12 buildGoModule rec {
  13   pname = "powerpipe";
  14   version = "0.4.0";
  15
  16   src = fetchFromGitHub {
  17     owner = "turbot";
  18     repo = "powerpipe";
  19     rev = "refs/tags/v${version}";
  20     hash = "sha256-KJ024dIU0GmeHCFa/pbyFIA+LitaudHC+NBGg8yNWxM=";
  21   };
  22
  23   vendorHash = "sha256-XALFXUeWrS4nt+ONToCfYXvLWuk7ZhLWvJidnATcWtM=";
  24   proxyVendor = true;
  25
  26   nativeBuildInputs = [
  27     installShellFiles
  28     makeWrapper
  29   ];
  30
  31   ldflags = [
  32     "-s"
  33     "-w"
  34     "-X main.version=${version}"
  35   ];
  36
  37   doCheck = true;
  38
  39   checkFlags =
  40     let
  41       skippedTests = [
  42         # test fails in the original github.com/turbot/powerpipe project as well
  43         "TestGetAsSnapshotPropertyMap/card"
  44       ];
  45     in
  46     [ "-skip=^${builtins.concatStringsSep "$|^" skippedTests}$" ];
  47
  48   postInstall = ''
  49     wrapProgram $out/bin/powerpipe \
  50       --set-default POWERPIPE_UPDATE_CHECK false \
  51       --set-default POWERPIPE_TELEMETRY none
  52   '';
  53
  54   passthru = {
  55     tests.version = testers.testVersion {
  56       command = "${lib.getExe powerpipe} --version";
  57       package = powerpipe;
  58       version = "v${version}";
  59     };
  60     updateScript = nix-update-script { };
  61   };
  62
  63   meta = {
  64     changelog = "https://github.com/turbot/powerpipe/blob/v${version}/CHANGELOG.md";
  65     description = "Dynamically query your cloud, code, logs & more with SQL";
  66     homepage = "https://powerpipe.io/";
  67     license = lib.licenses.agpl3Only;
  68     mainProgram = "powerpipe";
  69     maintainers = with lib.maintainers; [ weitzj ];
  70   };
  71 }