pkgs/by-name/sw/sword/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchurl,
   5   pkg-config,
   6   icu,
   7   clucene_core,
   8   curl,
   9 }:
  10
  11 stdenv.mkDerivation (finalAttrs: {
  12   pname = "sword";
  13   version = "1.9.0";
  14
  15   src = fetchurl {
  16     url = "https://www.crosswire.org/ftpmirror/pub/sword/source/v${lib.versions.majorMinor finalAttrs.version}/sword-${finalAttrs.version}.tar.gz";
  17     hash = "sha256-QkCc894vrxEIUj4sWsB0XSH57SpceO2HjuncwwNCa4o=";
  18   };
  19
  20   nativeBuildInputs = [ pkg-config ];
  21   buildInputs = [
  22     icu
  23     clucene_core
  24     curl
  25   ];
  26
  27   outputs = [
  28     "out"
  29     "dev"
  30   ];
  31
  32   prePatch = ''
  33     patchShebangs .;
  34   '';
  35
  36   configureFlags = [
  37     "--without-conf"
  38     "--enable-tests=no"
  39   ];
  40
  41   CXXFLAGS = [
  42     "-Wno-unused-but-set-variable"
  43     "-Wno-unknown-warning-option"
  44     # compat with icu61+ https://github.com/unicode-org/icu/blob/release-64-2/icu4c/readme.html#L554
  45     "-DU_USING_ICU_NAMESPACE=1"
  46   ];
  47
  48   meta = {
  49     description = "Software framework that allows research manipulation of Biblical texts";
  50     homepage = "https://www.crosswire.org/sword/";
  51     longDescription = ''
  52       The SWORD Project is the CrossWire Bible Society's free Bible software
  53       project. Its purpose is to create cross-platform open-source tools --
  54       covered by the GNU General Public License -- that allow programmers and
  55       Bible societies to write new Bible software more quickly and easily. We
  56       also create Bible study software for all readers, students, scholars, and
  57       translators of the Bible, and have a growing collection of many hundred
  58       texts in around 100 languages.
  59     '';
  60     license = lib.licenses.gpl2;
  61     maintainers = with lib.maintainers; [ AndersonTorres ];
  62     platforms = lib.platforms.unix;
  63   };
  64 })