pkgs/by-name/up/upsun/package.nix

   1 {
   2   stdenvNoCC,
   3   lib,
   4   fetchurl,
   5   testers,
   6   upsun
   7 }:
   8
   9 stdenvNoCC.mkDerivation (finalAttrs: {
  10   pname = "upsun";
  11   version = "5.0.13";
  12
  13   src =
  14     {
  15       x86_64-darwin = fetchurl {
  16         url = "https://github.com/platformsh/cli/releases/download/${finalAttrs.version}/upsun_${finalAttrs.version}_darwin_all.tar.gz";
  17         hash = "sha256-5JKXtAUnqrlufyNE05uZjEDfJv557auYPriTxvUbMJI=";
  18       };
  19       aarch64-darwin = fetchurl {
  20         url = "https://github.com/platformsh/cli/releases/download/${finalAttrs.version}/upsun_${finalAttrs.version}_darwin_all.tar.gz";
  21         hash = "sha256-5JKXtAUnqrlufyNE05uZjEDfJv557auYPriTxvUbMJI=";
  22       };
  23       x86_64-linux = fetchurl {
  24         url = "https://github.com/platformsh/cli/releases/download/${finalAttrs.version}/upsun_${finalAttrs.version}_linux_amd64.tar.gz";
  25         hash = "sha256-fjVL/sbO1wmaJ4qZpUMV/4Q4Jzf0p6qx0ElRdY5EUJU=";
  26       };
  27       aarch64-linux = fetchurl {
  28         url = "https://github.com/platformsh/cli/releases/download/${finalAttrs.version}/upsun_${finalAttrs.version}_linux_arm64.tar.gz";
  29         hash = "sha256-MNlQkwsg5SuIQJBDy7yVtcda1odpaUZezCgrat6OW2Q=";
  30       };
  31     }
  32     .${stdenvNoCC.system}
  33       or (throw "${finalAttrs.pname}-${finalAttrs.version}: ${stdenvNoCC.system} is unsupported.");
  34
  35   dontConfigure = true;
  36   dontBuild = true;
  37
  38   sourceRoot = ".";
  39   installPhase = ''
  40     runHook preInstall
  41
  42     install -Dm755 upsun $out/bin/upsun
  43
  44     runHook postInstall
  45   '';
  46
  47   passthru = {
  48     tests.version = testers.testVersion {
  49       inherit (finalAttrs) version;
  50       package = upsun;
  51     };
  52   };
  53
  54   meta = {
  55     description = "Unified tool for managing your Upsun services from the command line";
  56     homepage = "https://github.com/platformsh/cli";
  57     license = lib.licenses.mit;
  58     mainProgram = "upsun";
  59     maintainers = with lib.maintainers; [ spk ];
  60     platforms = [ "x86_64-linux" "aarch64-linux" "x86_64-darwin" "aarch64-darwin" ];
  61     sourceProvenance = with lib.sourceTypes; [ binaryNativeCode ];
  62   };
  63 })