pkgs/by-name/wl/wlogout/package.nix

   1 { lib
   2 , fetchFromGitHub
   3 , gitUpdater
   4 , gtk-layer-shell
   5 , gtk3
   6 , libxkbcommon
   7 , meson
   8 , ninja
   9 , pkg-config
  10 , scdoc
  11 , stdenv
  12 , wayland
  13 , wayland-protocols
  14 # gtk-layer-shell fails to cross-compile due to a hard dependency
  15 # on gobject-introspection.
  16 # Disable it when cross-compiling since it's an optional dependency.
  17 # This disables transparency support.
  18 , withGtkLayerShell ? (stdenv.buildPlatform == stdenv.hostPlatform)
  19 }:
  20
  21 stdenv.mkDerivation (finalAttrs: {
  22   pname = "wlogout";
  23   version = "1.2.2";
  24
  25   src = fetchFromGitHub {
  26     owner = "ArtsyMacaw";
  27     repo = "wlogout";
  28     rev = finalAttrs.version;
  29     hash = "sha256-/tYZy56ku68ziSOhy6Dex9RGy+blkU6CN2ze76y7718=";
  30   };
  31
  32   outputs = [ "out" "man" ];
  33
  34   depsBuildBuild = [
  35     pkg-config
  36   ];
  37
  38   nativeBuildInputs = [
  39     meson
  40     ninja
  41     pkg-config
  42     scdoc
  43   ];
  44
  45   buildInputs = [
  46     gtk3
  47     libxkbcommon
  48     wayland
  49     wayland-protocols
  50   ] ++ lib.optionals withGtkLayerShell [
  51     gtk-layer-shell
  52   ];
  53
  54   strictDeps = true;
  55
  56   mesonFlags = [
  57     "--datadir=${placeholder "out"}/share"
  58     "--sysconfdir=${placeholder "out"}/etc"
  59   ];
  60
  61   postPatch = ''
  62     substituteInPlace style.css \
  63       --replace "/usr/share/wlogout" "$out/share/wlogout"
  64
  65     substituteInPlace main.c \
  66       --replace "/etc/wlogout" "$out/etc/wlogout"
  67   '';
  68
  69   passthru = {
  70     updateScript = gitUpdater { };
  71   };
  72
  73   meta = {
  74     homepage = "https://github.com/ArtsyMacaw/wlogout";
  75     description = "Wayland based logout menu";
  76     changelog = "https://github.com/ArtsyMacaw/wlogout/releases/tag/${finalAttrs.src.rev}";
  77     license = with lib.licenses; [ mit ];
  78     mainProgram = "wlogout";
  79     maintainers = with lib.maintainers; [ AndersonTorres ];
  80     inherit (wayland.meta) platforms;
  81   };
  82 })