pkgs/development/coq-modules/dpdgraph/default.nix

   1 { lib, mkCoqDerivation, autoreconfHook, coq, version ? null }:
   2
   3 with lib;
   4 let hasWarning = versionAtLeast coq.ocamlPackages.ocaml.version "4.08"; in
   5
   6 mkCoqDerivation {
   7   pname = "dpdgraph";
   8   owner = "Karmaki";
   9   repo = "coq-dpdgraph";
  10   inherit version;
  11   defaultVersion = switch coq.coq-version [
  12     { case = "8.13"; out = "0.6.9"; }
  13     { case = "8.12"; out = "0.6.8"; }
  14     { case = "8.11"; out = "0.6.7"; }
  15     { case = "8.10"; out = "0.6.6"; }
  16     { case = "8.9";  out = "0.6.5"; }
  17     { case = "8.8";  out = "0.6.3"; }
  18     { case = "8.7";  out = "0.6.2"; }
  19     { case = "8.6";  out = "0.6.1"; }
  20     { case = "8.5";  out = "0.6"; }
  21   ] null;
  22
  23   release."0.6.9".sha256 = "11mbydpcgk7y8pqzickbzx0ig7g9k9al71i9yfrcscd2xj8fwj8z";
  24   release."0.6.8".sha256 = "1mj6sknsd53xfb387sp3kdwvl4wn80ck24bfzf3s6mgw1a12vyps";
  25   release."0.6.7".sha256 = "01vpi7scvkl4ls1z2k2x9zd65wflzb667idj759859hlz3ps9z09";
  26   release."0.6.6".sha256 = "1gjrm5zjzw4cisiwdr5b3iqa7s4cssa220xr0k96rwgk61rcjd8w";
  27   release."0.6.5".sha256 = "1f34z24yg05b1096gqv36jr3vffkcjkf9qncii3pzhhvagxd0w2f";
  28   release."0.6.3".rev    = "0acbd0a594c7e927574d5f212cc73a486b5305d2";
  29   release."0.6.3".sha256 = "0c95b0bz2kjm6swr5na4gs06lxxywradszxbr5ldh2zx02r3f3rx";
  30   release."0.6.2".rev    = "d76ddde37d918569945774733b7997e8b24daf51";
  31   release."0.6.2".sha256 = "04lnf4b25yarysj848cfl8pd3i3pr3818acyp9hgwdgd1rqmhjwm";
  32   release."0.6.1".rev    = "c3b87af6bfa338e18b83f014ebd0e56e1f611663";
  33   release."0.6.1".sha256 = "1jaafkwsb5450378nprjsds1illgdaq60gryi8kspw0i25ykz2c9";
  34   release."0.6".sha256   = "0qvar8gfbrcs9fmvkph5asqz4l5fi63caykx3bsn8zf0xllkwv0n";
  35   releaseRev = v: "v${v}";
  36
  37   nativeBuildInputs = [ autoreconfHook ];
  38   mlPlugin = true;
  39   extraBuildInputs = [ coq.ocamlPackages.ocamlgraph ];
  40
  41   # dpd_compute.ml uses deprecated Pervasives.compare
  42   # Versions prior to 0.6.5 do not have the WARN_ERR build flag
  43   preConfigure = optionalString hasWarning ''
  44     substituteInPlace Makefile.in --replace "-warn-error +a " ""
  45   '';
  46
  47   buildFlags = optional hasWarning "WARN_ERR=";
  48
  49   preInstall = ''
  50     mkdir -p $out/bin
  51   '';
  52
  53   extraInstallFlags = [ "BINDIR=$(out)/bin" ];
  54
  55   meta = {
  56     description = "Build dependency graphs between Coq objects";
  57     license = licenses.lgpl21;
  58     maintainers = with maintainers; [ vbgl ];
  59   };
  60 }