pkgs/development/coq-modules/mathcomp-analysis/default.nix

   1 { coq, mkCoqDerivation, mathcomp, mathcomp-finmap, mathcomp-bigenough, mathcomp-real-closed,
   2   hierarchy-builder, lib, version ? null }:
   3
   4 with lib;
   5 let mca = mkCoqDerivation {
   6
   7   namePrefix = [ "coq" "mathcomp" ];
   8   pname = "analysis";
   9   owner = "math-comp";
  10
  11   release."0.3.6".sha256 = "0g2j7b2hca4byz62ssgg90bkbc8wwp7xkb2d3225bbvihi92b4c5";
  12   release."0.3.4".sha256 = "18mgycjgg829dbr7ps77z6lcj03h3dchjbj5iir0pybxby7gd45c";
  13   release."0.3.3".sha256 = "1m2mxcngj368vbdb8mlr91hsygl430spl7lgyn9qmn3jykack867";
  14   release."0.3.1".sha256 = "1iad288yvrjv8ahl9v18vfblgqb1l5z6ax644w49w9hwxs93f2k8";
  15   release."0.2.3".sha256 = "0p9mr8g1qma6h10qf7014dv98ln90dfkwn76ynagpww7qap8s966";
  16
  17   inherit version;
  18   defaultVersion = with versions; switch [ coq.version mathcomp.version ]  [
  19       { cases = [ (range "8.11" "8.13") "1.12.0" ];             out = "0.3.6"; }
  20       { cases = [ (range "8.11" "8.13") "1.11.0" ];             out = "0.3.4"; }
  21       { cases = [ (range "8.10" "8.12") "1.11.0" ];             out = "0.3.3"; }
  22       { cases = [ (range "8.10" "8.11") "1.11.0" ];             out = "0.3.1"; }
  23       { cases = [ (range "8.8"  "8.11") (range "1.8" "1.10") ]; out = "0.2.3"; }
  24     ] null;
  25
  26   propagatedBuildInputs =
  27     [ mathcomp.ssreflect mathcomp.field
  28       mathcomp-finmap mathcomp-bigenough mathcomp-real-closed ];
  29
  30   meta = {
  31     description = "Analysis library compatible with Mathematical Components";
  32     maintainers = [ maintainers.cohencyril ];
  33     license = licenses.cecill-c;
  34   };
  35 }; in
  36 mca.overrideAttrs (o:
  37   let ext = { propagatedBuildInputs = o.propagatedBuildInputs
  38                                       ++ [ hierarchy-builder ]; };
  39   in with versions; switch o.version [
  40     {case = "dev";        out = ext;}
  41     {case = isGe "0.3.4"; out = ext;}
  42   ] {}
  43 )