pkgs/development/libraries/argp-standalone/default.nix

   1 { lib, stdenv, fetchurl, fetchpatch }:
   2
   3 let
   4   patch-argp-fmtstream = fetchpatch {
   5     name = "patch-argp-fmtstream.h";
   6     url = "https://raw.githubusercontent.com/Homebrew/formula-patches/b5f0ad3/argp-standalone/patch-argp-fmtstream.h";
   7     sha256 = "5656273f622fdb7ca7cf1f98c0c9529bed461d23718bc2a6a85986e4f8ed1cb8";
   8   };
   9
  10   patch-throw-in-funcdef = fetchpatch {
  11     name = "argp-standalone-1.3-throw-in-funcdef.patch";
  12     url = "https://gitweb.gentoo.org/repo/gentoo.git/plain/sys-libs/argp-standalone/files/argp-standalone-1.3-throw-in-funcdef.patch?id=409d0e2a9c9c899fb1fb04cc808fe0aff3f745ca";
  13     sha256 = "0b2b4l1jkvmnffl22jcn4ydzxy2i7fnmmnfim12f0yg5pb8fs43c";
  14   };
  15
  16   patch-shared = fetchpatch {
  17     name = "argp-standalone-1.3-shared.patch";
  18     url = "https://gitweb.gentoo.org/repo/gentoo.git/plain/sys-libs/argp-standalone/files/argp-standalone-1.3-shared.patch?id=409d0e2a9c9c899fb1fb04cc808fe0aff3f745ca";
  19     sha256 = "1xx2zdc187a1m2x6c1qs62vcrycbycw7n0q3ks2zkxpaqzx2dgkw";
  20   };
  21 in
  22 stdenv.mkDerivation {
  23   name = "argp-standalone-1.3";
  24
  25   src = fetchurl {
  26     url = "https://www.lysator.liu.se/~nisse/misc/argp-standalone-1.3.tar.gz";
  27     sha256 = "dec79694da1319acd2238ce95df57f3680fea2482096e483323fddf3d818d8be";
  28   };
  29
  30   patches =
  31        lib.optionals stdenv.hostPlatform.isDarwin [ patch-argp-fmtstream ]
  32     ++ lib.optionals stdenv.hostPlatform.isLinux [ patch-throw-in-funcdef patch-shared ];
  33
  34   patchFlags = lib.optional stdenv.hostPlatform.isDarwin "-p0";
  35
  36   preConfigure = lib.optionalString stdenv.hostPlatform.isLinux "export CFLAGS='-fgnu89-inline'";
  37
  38   postInstall = ''
  39     mkdir -p $out/lib $out/include
  40     cp libargp.a $out/lib
  41     cp argp.h $out/include
  42   '';
  43
  44   doCheck = true;
  45
  46   makeFlags = [ "AR:=$(AR)" ];
  47
  48   enableParallelBuilding = true;
  49
  50   meta = with lib; {
  51     homepage = "https://www.lysator.liu.se/~nisse/misc/";
  52     description = "Standalone version of arguments parsing functions from GLIBC";
  53     platforms = with platforms; darwin ++ linux;
  54     maintainers = with maintainers; [ amar1729 ];
  55     license = licenses.gpl2;
  56   };
  57 }