pkgs/development/libraries/cogl/default.nix

   1 { lib, stdenv, fetchurl, fetchpatch, pkg-config, libGL, glib, gdk-pixbuf, xorg, libintl
   2 , pangoSupport ? true, pango, cairo, gobject-introspection, wayland, gnome3
   3 , mesa, automake, autoconf
   4 , gstreamerSupport ? true, gst_all_1 }:
   5
   6 let
   7   pname = "cogl";
   8 in stdenv.mkDerivation rec {
   9   name = "${pname}-${version}";
  10   version = "1.22.8";
  11
  12   src = fetchurl {
  13     url = "mirror://gnome/sources/${pname}/${lib.versions.majorMinor version}/${name}.tar.xz";
  14     sha256 = "0nfph4ai60ncdx7hy6hl1i1cmp761jgnyjfhagzi0iqq36qb41d8";
  15   };
  16
  17   patches = [
  18     # Some deepin packages need the following patches. They have been
  19     # submitted by Fedora on the GNOME Bugzilla
  20     # (https://bugzilla.gnome.org/787443). Upstream thinks the patch
  21     # could be merged, but dev can not make a new release.
  22
  23     (fetchpatch {
  24       url = "https://bug787443.bugzilla-attachments.gnome.org/attachment.cgi?id=359589";
  25       sha256 = "0f0d9iddg8zwy853phh7swikg4yzhxxv71fcag36f8gis0j5p998";
  26     })
  27
  28     (fetchpatch {
  29       url = "https://bug787443.bugzilla-attachments.gnome.org/attachment.cgi?id=361056";
  30       sha256 = "09fyrdci4727fg6qm5aaapsbv71sf4wgfaqz8jqlyy61dibgg490";
  31     })
  32   ];
  33
  34   outputs = [ "out" "dev" ];
  35
  36   nativeBuildInputs = [ pkg-config libintl automake autoconf ];
  37
  38   configureFlags = [
  39     "--enable-introspection"
  40     "--enable-kms-egl-platform"
  41     "--enable-wayland-egl-platform"
  42     "--enable-wayland-egl-server"
  43   ] ++ lib.optional gstreamerSupport "--enable-cogl-gst"
  44   ++ lib.optionals (!stdenv.isDarwin) [ "--enable-gles1" "--enable-gles2" ];
  45
  46   propagatedBuildInputs = with xorg; [
  47       glib gdk-pixbuf gobject-introspection wayland mesa
  48       libGL libXrandr libXfixes libXcomposite libXdamage
  49     ]
  50     ++ lib.optionals gstreamerSupport [ gst_all_1.gstreamer
  51                                                gst_all_1.gst-plugins-base ];
  52
  53   buildInputs = lib.optionals pangoSupport [ pango cairo ];
  54
  55   COGL_PANGO_DEP_CFLAGS
  56     = lib.optionalString (stdenv.isDarwin && pangoSupport)
  57       "-I${pango.dev}/include/pango-1.0 -I${cairo.dev}/include/cairo";
  58
  59   #doCheck = true; # all tests fail (no idea why)
  60
  61   passthru = {
  62     updateScript = gnome3.updateScript {
  63       packageName = pname;
  64     };
  65   };
  66
  67   meta = with lib; {
  68     description = "A small open source library for using 3D graphics hardware for rendering";
  69     maintainers = with maintainers; [ lovek323 ];
  70
  71     longDescription = ''
  72       Cogl is a small open source library for using 3D graphics hardware for
  73       rendering. The API departs from the flat state machine style of OpenGL
  74       and is designed to make it easy to write orthogonal components that can
  75       render without stepping on each other's toes.
  76     '';
  77
  78     platforms = platforms.mesaPlatforms;
  79     license = with licenses; [ mit bsd3 publicDomain sgi-b-20 ];
  80   };
  81 }