pkgs/development/libraries/gtksourceview/3.x.nix

   1 { lib, stdenv, fetchurl, pkg-config, atk, cairo, glib, gtk3, pango, vala
   2 , libxml2, perl, intltool, gettext, gobject-introspection, dbus, xvfb_run, shared-mime-info }:
   3
   4 stdenv.mkDerivation rec {
   5   pname = "gtksourceview";
   6   version = "3.24.11";
   7
   8   src = fetchurl {
   9     url = "mirror://gnome/sources/gtksourceview/${lib.versions.majorMinor version}/${pname}-${version}.tar.xz";
  10     sha256 = "1zbpj283b5ycz767hqz5kdq02wzsga65pp4fykvhg8xj6x50f6v9";
  11   };
  12
  13   propagatedBuildInputs = [
  14     # Required by gtksourceview-3.0.pc
  15     gtk3
  16     # Used by gtk_source_language_manager_guess_language
  17     shared-mime-info
  18   ];
  19
  20   outputs = [ "out" "dev" ];
  21
  22   nativeBuildInputs = [ pkg-config intltool perl gobject-introspection vala ];
  23
  24   checkInputs = [ xvfb_run dbus ];
  25
  26   buildInputs = [ atk cairo glib pango libxml2 gettext ];
  27
  28   preBuild = ''
  29     substituteInPlace gtksourceview/gtksourceview-utils.c --replace "@NIX_SHARE_PATH@" "$out/share"
  30   '';
  31
  32   patches = [ ./3.x-nix_share_path.patch ];
  33
  34   enableParallelBuilding = true;
  35
  36   doCheck = stdenv.isLinux;
  37   checkPhase = ''
  38     NO_AT_BRIDGE=1 \
  39     XDG_DATA_DIRS="$XDG_DATA_DIRS:${shared-mime-info}/share" \
  40     xvfb-run -s '-screen 0 800x600x24' dbus-run-session \
  41       --config-file=${dbus.daemon}/share/dbus-1/session.conf \
  42       make check
  43   '';
  44
  45   meta = with lib; {
  46     homepage = "https://wiki.gnome.org/Projects/GtkSourceView";
  47     platforms = with platforms; linux ++ darwin;
  48     license = licenses.lgpl21;
  49     maintainers = teams.gnome.members;
  50   };
  51 }