pkgs/development/libraries/libcanberra/default.nix

   1 { stdenv, lib, fetchurl, fetchpatch, pkg-config, libtool
   2 , gtk ? null
   3 , libpulseaudio, gst_all_1, libvorbis, libcap
   4 , CoreServices
   5 , withAlsa ? stdenv.isLinux, alsaLib }:
   6
   7 stdenv.mkDerivation rec {
   8   name = "libcanberra-0.30";
   9
  10   src = fetchurl {
  11     url = "http://0pointer.de/lennart/projects/libcanberra/${name}.tar.xz";
  12     sha256 = "0wps39h8rx2b00vyvkia5j40fkak3dpipp1kzilqla0cgvk73dn2";
  13   };
  14
  15   nativeBuildInputs = [ pkg-config libtool ];
  16   buildInputs = [
  17     libpulseaudio libvorbis gtk
  18   ] ++ (with gst_all_1; [ gstreamer gst-plugins-base ])
  19     ++ lib.optional stdenv.isDarwin CoreServices
  20     ++ lib.optional stdenv.isLinux libcap
  21     ++ lib.optional withAlsa alsaLib;
  22
  23   configureFlags = [ "--disable-oss" ];
  24
  25   patches = [
  26     (fetchpatch {
  27       name = "0001-gtk-Don-t-assume-all-GdkDisplays-are-GdkX11Displays-.patch";
  28       url = "http://git.0pointer.net/libcanberra.git/patch/?id=c0620e432650e81062c1967cc669829dbd29b310";
  29       sha256 = "0rc7zwn39yxzxp37qh329g7375r5ywcqcaak8ryd0dgvg8m5hcx9";
  30     })
  31   ];
  32
  33   postPatch = (lib.optional stdenv.isDarwin) ''
  34     patch -p0 < ${fetchpatch {
  35       url = "https://raw.githubusercontent.com/macports/macports-ports/master/audio/libcanberra/files/patch-configure.diff";
  36       sha256 = "1f7h7ifpqvbfhqygn1b7klvwi80zmpv3538vbmq7ql7bkf1q8h31";
  37     }}
  38   '';
  39
  40   postInstall = ''
  41     for f in $out/lib/*.la; do
  42       sed 's|-lltdl|-L${libtool.lib}/lib -lltdl|' -i $f
  43     done
  44   '';
  45
  46   passthru = {
  47     gtkModule = "/lib/gtk-2.0/";
  48   };
  49
  50   meta = with lib; {
  51     description = "An implementation of the XDG Sound Theme and Name Specifications";
  52     longDescription = ''
  53       libcanberra is an implementation of the XDG Sound Theme and Name
  54       Specifications, for generating event sounds on free desktops
  55       such as GNOME.  It comes with several backends (ALSA,
  56       PulseAudio, OSS, GStreamer, null) and is designed to be
  57       portable.
  58     '';
  59     homepage = "http://0pointer.de/lennart/projects/libcanberra/";
  60     license = licenses.lgpl2Plus;
  61     maintainers = [ ];
  62     platforms = platforms.unix;
  63     # canberra-gtk-module.c:28:10: fatal error: 'gdk/gdkx.h' file not found
  64     # #include <gdk/gdkx.h>
  65     broken = stdenv.isDarwin;
  66   };
  67 }