pkgs/development/libraries/libcef/default.nix

   1 { lib, stdenv, fetchurl, cmake, alsaLib, atk, cairo, cups, dbus, expat, fontconfig
   2 , GConf, gdk-pixbuf, glib, gtk2, libX11, libxcb, libXcomposite, libXcursor
   3 , libXdamage, libXext, libXfixes, libXi, libXrandr, libXrender, libXScrnSaver
   4 , libXtst, nspr, nss, pango, libpulseaudio, systemd, at-spi2-atk, at-spi2-core
   5 }:
   6
   7 let
   8   libPath =
   9     lib.makeLibraryPath [
  10       alsaLib atk cairo cups dbus expat fontconfig GConf gdk-pixbuf glib gtk2
  11       libX11 libxcb libXcomposite libXcursor libXdamage libXext libXfixes libXi
  12       libXrandr libXrender libXScrnSaver libXtst nspr nss pango libpulseaudio
  13       systemd at-spi2-core at-spi2-atk
  14     ];
  15 in
  16 stdenv.mkDerivation rec {
  17   pname = "cef-binary";
  18   version = "75.1.14-gc81164e";
  19
  20   src = fetchurl {
  21     name = "cef_binary_75.1.14+gc81164e+chromium-75.0.3770.100_linux64_minimal.tar.bz2";
  22     url = "http://opensource.spotify.com/cefbuilds/cef_binary_75.1.14%2Bgc81164e%2Bchromium-75.0.3770.100_linux64_minimal.tar.bz2";
  23     sha256 = "0985b2bx505j0q693hifjgidzb597wqf5idql5aqxs8lfxhc2pgg";
  24   };
  25
  26   nativeBuildInputs = [ cmake ];
  27   makeFlags = [ "libcef_dll_wrapper" ];
  28   dontStrip = true;
  29   dontPatchELF = true;
  30
  31   installPhase = ''
  32     mkdir -p $out/lib/ $out/share/cef/
  33     cp libcef_dll_wrapper/libcef_dll_wrapper.a $out/lib/
  34     cp ../Release/libcef.so $out/lib/
  35     patchelf --set-rpath "${libPath}" $out/lib/libcef.so
  36     cp ../Release/*.bin $out/share/cef/
  37     cp -r ../Resources/* $out/share/cef/
  38     cp -r ../include $out/
  39   '';
  40
  41   meta = with lib; {
  42     description = "Simple framework for embedding Chromium-based browsers in other applications";
  43     homepage = "http://opensource.spotify.com/cefbuilds/index.html";
  44     maintainers = with maintainers; [ puffnfresh ];
  45     license = licenses.bsd3;
  46     platforms = with platforms; linux;
  47   };
  48 }