pkgs/development/libraries/libgpod/default.nix

   1 { stdenv, lib, fetchurl, perlPackages, intltool, autoreconfHook,
   2   pkg-config, glib, libxml2, sqlite, zlib, sg3_utils, gdk-pixbuf, taglib,
   3   libimobiledevice,
   4   monoSupport ? false, mono, gtk-sharp-2_0
   5 }:
   6
   7
   8 stdenv.mkDerivation rec {
   9   name = "libgpod-0.8.3";
  10
  11   src = fetchurl {
  12     url = "mirror://sourceforge/gtkpod/${name}.tar.bz2";
  13     sha256 = "0pcmgv1ra0ymv73mlj4qxzgyir026z9jpl5s5bkg35afs1cpk2k3";
  14   };
  15
  16   outputs = [ "out" "dev" ];
  17
  18   postPatch = ''
  19     # support libplist 2.2
  20     substituteInPlace configure.ac --replace 'libplist >= 1.0' 'libplist-2.0 >= 2.2'
  21   '';
  22
  23   configureFlags = [
  24     "--without-hal"
  25     "--enable-udev"
  26     "--with-udev-dir=${placeholder "out"}/lib/udev"
  27   ] ++ lib.optionals monoSupport [ "--with-mono" ];
  28
  29   dontStrip = true;
  30
  31   propagatedBuildInputs = [ glib libxml2 sqlite zlib sg3_utils
  32     gdk-pixbuf taglib libimobiledevice ];
  33
  34   nativeBuildInputs = [ autoreconfHook intltool pkg-config ]
  35     ++ (with perlPackages; [ perl XMLParser ])
  36     ++ lib.optionals monoSupport [ mono gtk-sharp-2_0 ];
  37
  38   meta = {
  39     homepage = "https://gtkpod.sourceforge.net/";
  40     description = "Library used by gtkpod to access the contents of an ipod";
  41     license = "LGPL";
  42     platforms = lib.platforms.gnu ++ lib.platforms.linux;
  43     maintainers = [ ];
  44   };
  45 }