pkgs/development/libraries/libhugetlbfs/default.nix

   1 { stdenv, lib, fetchurl }:
   2
   3 stdenv.mkDerivation rec {
   4   pname = "libhugetlbfs";
   5   version = "2.23";
   6
   7   src = fetchurl {
   8     url = "https://github.com/libhugetlbfs/libhugetlbfs/releases/download/${version}/libhugetlbfs-${version}.tar.gz";
   9     sha256 = "0ya4q001g111d3pqlzrf3yaifadl0ccirx5dndz1pih7x3qp41mp";
  10   };
  11
  12   outputs = [ "bin" "dev" "man" "doc" "lib" "out" ];
  13
  14   postConfigure = ''
  15     patchShebangs ld.hugetlbfs
  16   '';
  17
  18   enableParallelBuilding = true;
  19   makeFlags = [
  20     "BUILDTYPE=NATIVEONLY"
  21     "PREFIX=$(out)"
  22     "HEADERDIR=$(dev)/include"
  23     "LIBDIR32=$(lib)/$(LIB32)"
  24     "LIBDIR64=$(lib)/$(LIB64)"
  25     "EXEDIR=$(bin)/bin"
  26     "DOCDIR=$(doc)/share/doc/libhugetlbfs"
  27     "MANDIR=$(man)/share/man"
  28   ];
  29
  30   # Default target builds tests as well, and the tests want a static
  31   # libc.
  32   buildFlags = [ "libs" "tools" ];
  33   installTargets = [ "install" "install-docs" ];
  34
  35   meta = with lib; {
  36     description = "library and utilities for Linux hugepages";
  37     maintainers = with maintainers; [ qyliss ];
  38     license = licenses.lgpl21Plus;
  39     platforms = platforms.linux;
  40   };
  41 }