pkgs/development/libraries/libiio/default.nix

   1 { stdenv
   2 , fetchFromGitHub
   3 , cmake
   4 , flex
   5 , bison
   6 , libxml2
   7 , python
   8 , libusb1
   9 , runtimeShell
  10 , lib
  11 }:
  12
  13 stdenv.mkDerivation rec {
  14   pname = "libiio";
  15   version = "0.21";
  16
  17   outputs = [ "out" "lib" "dev" "python" ];
  18
  19   src = fetchFromGitHub {
  20     owner = "analogdevicesinc";
  21     repo = "libiio";
  22     rev = "v${version}";
  23     sha256 = "0psw67mzysdb8fkh8xpcwicm7z94k8plkcc8ymxyvl6inshq0mc7";
  24   };
  25
  26   nativeBuildInputs = [
  27     cmake
  28     flex
  29     bison
  30   ];
  31
  32   buildInputs = [
  33     python
  34     libxml2
  35     libusb1
  36   ] ++ lib.optional python.isPy3k python.pkgs.setuptools;
  37
  38   cmakeFlags = [
  39     "-DUDEV_RULES_INSTALL_DIR=${placeholder "out"}/lib/udev/rules.d"
  40     "-DPYTHON_BINDINGS=on"
  41   ];
  42
  43   postPatch = ''
  44     # Hardcode path to the shared library into the bindings.
  45     sed "s#@libiio@#$lib/lib/libiio${stdenv.hostPlatform.extensions.sharedLibrary}#g" ${./hardcode-library-path.patch} | patch -p1
  46
  47     substituteInPlace libiio.rules.cmakein \
  48       --replace /bin/sh ${runtimeShell}
  49   '';
  50
  51   postInstall = ''
  52     # Move Python bindings into a separate output.
  53     moveToOutput ${python.sitePackages} "$python"
  54   '';
  55
  56   meta = with lib; {
  57     description = "API for interfacing with the Linux Industrial I/O Subsystem";
  58     homepage = "https://github.com/analogdevicesinc/libiio";
  59     license = licenses.lgpl21Plus;
  60     platforms = platforms.linux;
  61     maintainers = with maintainers; [ thoughtpolice ];
  62   };
  63 }