pkgs/development/libraries/liburing/default.nix

   1 { lib, stdenv, fetchgit
   2 , fetchpatch
   3 }:
   4
   5 stdenv.mkDerivation rec {
   6   pname = "liburing";
   7   version = "2.0";
   8
   9   src = fetchgit {
  10     url    = "http://git.kernel.dk/${pname}";
  11     rev    = "liburing-${version}";
  12     sha256 = "0has1yd1ns5q5jgcmhrbgwhbwq0wix3p7xv3dyrwdf784p56izkn";
  13   };
  14
  15   separateDebugInfo = true;
  16   enableParallelBuilding = true;
  17   # Upstream's configure script is not autoconf generated, but a hand written one.
  18   setOutputFlags = false;
  19   preConfigure =
  20     # We cannot use configureFlags or configureFlagsArray directly, since we
  21     # don't have structuredAttrs yet and using placeholder causes permissions
  22     # denied errors. Using $dev / $man in configureFlags causes bash evaluation
  23     # errors
  24   ''
  25     configureFlagsArray+=(
  26       "--includedir=$dev/include"
  27       "--mandir=$man/share/man"
  28     )
  29   '';
  30
  31   # Doesn't recognize platform flags
  32   configurePlatforms = [];
  33
  34   outputs = [ "out" "bin" "dev" "man" ];
  35
  36   postInstall =
  37   # Copy the examples into $bin. Most reverse dependency of this package should
  38   # reference only the $out output
  39   ''
  40     mkdir -p $bin/bin
  41     cp ./examples/io_uring-cp examples/io_uring-test $bin/bin
  42     cp ./examples/link-cp $bin/bin/io_uring-link-cp
  43     cp ./examples/ucontext-cp $bin/bin/io_uring-ucontext-cp
  44   ''
  45   ;
  46
  47   meta = with lib; {
  48     description = "Userspace library for the Linux io_uring API";
  49     homepage    = "https://git.kernel.dk/cgit/liburing/";
  50     license     = licenses.lgpl21;
  51     platforms   = platforms.linux;
  52     maintainers = with maintainers; [ thoughtpolice ];
  53   };
  54 }