pkgs/development/libraries/opencolorio/default.nix

   1 { stdenv, lib, fetchFromGitHub, cmake, boost, pkg-config, lcms2, tinyxml, git }:
   2
   3 with lib;
   4
   5 stdenv.mkDerivation rec {
   6   pname = "opencolorio";
   7   version = "1.1.1";
   8
   9   src = fetchFromGitHub {
  10     owner = "imageworks";
  11     repo = "OpenColorIO";
  12     rev = "v${version}";
  13     sha256 = "12srvxca51czpfjl0gabpidj9n84mw78ivxy5w75qhq2mmc798sb";
  14   };
  15
  16   outputs = [ "bin" "out" "dev" ];
  17
  18   # TODO: Investigate whether git can be dropped: It's only used to apply patches
  19   nativeBuildInputs = [ cmake pkg-config git ];
  20
  21   buildInputs = [ lcms2 tinyxml ] ++ optional stdenv.isDarwin boost;
  22
  23   postPatch = ''
  24     substituteInPlace src/core/CMakeLists.txt --replace "-Werror" ""
  25     substituteInPlace src/pyglue/CMakeLists.txt --replace "-Werror" ""
  26   '';
  27
  28   cmakeFlags = [
  29     "-DUSE_EXTERNAL_LCMS=ON"
  30     "-DUSE_EXTERNAL_TINYXML=ON"
  31     # External libyamlcpp 0.6.* not compatible: https://github.com/imageworks/OpenColorIO/issues/517
  32     "-DUSE_EXTERNAL_YAML=OFF"
  33   ] ++ optional stdenv.isDarwin "-DOCIO_USE_BOOST_PTR=ON"
  34     ++ optional (!stdenv.hostPlatform.isi686 && !stdenv.hostPlatform.isx86_64) "-DOCIO_USE_SSE=OFF";
  35
  36   postInstall = ''
  37     mkdir -p $bin/bin; mv $out/bin $bin/
  38   '';
  39
  40   meta = with lib; {
  41     homepage = "https://opencolorio.org";
  42     description = "A color management framework for visual effects and animation";
  43     license = licenses.bsd3;
  44     maintainers = [ maintainers.goibhniu ];
  45     platforms = platforms.unix;
  46   };
  47 }