pkgs/development/libraries/poppler/0.61.nix

   1 { stdenv, lib, fetchurl, cmake, ninja, pkg-config, libiconv, libintl
   2 , zlib, curl, cairo, freetype, fontconfig, lcms, libjpeg, openjpeg, fetchpatch
   3 , withData ? true, poppler_data
   4 , qt5Support ? false, qtbase ? null
   5 , introspectionSupport ? false, gobject-introspection ? null
   6 , utils ? false
   7 , minimal ? false, suffix ? "glib"
   8 }:
   9
  10 let
  11   version = "0.61.1";
  12   mkFlag = optset: flag: "-DENABLE_${flag}=${if optset then "on" else "off"}";
  13 in
  14 stdenv.mkDerivation rec {
  15   name = "poppler-${suffix}-${version}";
  16
  17   src = fetchurl {
  18     url = "${meta.homepage}/poppler-${version}.tar.xz";
  19     sha256 = "1afdrxxkaivvviazxkg5blsf2x24sjkfj92ib0d3q5pm8dihjrhj";
  20   };
  21
  22   outputs = [ "out" "dev" ];
  23
  24   patches = [
  25     (fetchpatch {
  26       name = "CVE-2018-13988";
  27       url = "https://cgit.freedesktop.org/poppler/poppler/patch/?id=004e3c10df0abda214f0c293f9e269fdd979c5ee";
  28       sha256 = "1l8713s57xc6g81bldw934rsfm140fqc7ggd50ha5mxdl1b3app2";
  29     })
  30     ./0.61-CVE-2019-9959.patch
  31   ];
  32
  33   buildInputs = [ libiconv libintl ] ++ lib.optional withData poppler_data;
  34
  35   # TODO: reduce propagation to necessary libs
  36   propagatedBuildInputs = with lib;
  37     [ zlib freetype fontconfig libjpeg openjpeg ]
  38     ++ optionals (!minimal) [ cairo lcms curl ]
  39     ++ optional qt5Support qtbase
  40     ++ optional introspectionSupport gobject-introspection;
  41
  42   nativeBuildInputs = [ cmake ninja pkg-config ];
  43
  44   # Not sure when and how to pass it.  It seems an upstream bug anyway.
  45   CXXFLAGS = lib.optionalString stdenv.cc.isClang "-std=c++11";
  46
  47   cmakeFlags = [
  48     (mkFlag true "XPDF_HEADERS")
  49     (mkFlag (!minimal) "GLIB")
  50     (mkFlag (!minimal) "CPP")
  51     (mkFlag (!minimal) "LIBCURL")
  52     (mkFlag utils "UTILS")
  53     (mkFlag qt5Support "QT5")
  54   ];
  55
  56   dontWrapQtApps = true;
  57
  58   meta = with lib; {
  59     homepage = "https://poppler.freedesktop.org/";
  60     description = "A PDF rendering library";
  61
  62     longDescription = ''
  63       Poppler is a PDF rendering library based on the xpdf-3.0 code base.
  64     '';
  65
  66     license = licenses.gpl2;
  67     platforms = platforms.all;
  68     maintainers = with maintainers; [ ttuegel ];
  69   };
  70 }