pkgs/development/libraries/qt-5/qtModule.nix

   1 { lib, mkDerivation, perl }:
   2
   3 let inherit (lib) licenses maintainers platforms; in
   4
   5 { self, srcs, patches }:
   6
   7 args:
   8
   9 let
  10   inherit (args) name;
  11   version = args.version or srcs.${name}.version;
  12   src = args.src or srcs.${name}.src;
  13 in
  14
  15 mkDerivation (args // {
  16   name = "${name}-${version}";
  17   inherit src;
  18   patches = args.patches or patches.${name} or [];
  19
  20   nativeBuildInputs = (args.nativeBuildInputs or []) ++ [ perl self.qmake ];
  21   propagatedBuildInputs = args.qtInputs ++ (args.propagatedBuildInputs or []);
  22
  23   outputs = args.outputs or [ "out" "dev" ];
  24   setOutputFlags = args.setOutputFlags or false;
  25
  26   preHook = ''
  27     . ${./hooks/move-qt-dev-tools.sh}
  28     . ${./hooks/fix-qt-builtin-paths.sh}
  29   '';
  30
  31   preConfigure = ''
  32     ${args.preConfigure or ""}
  33
  34     fixQtBuiltinPaths . '*.pr?'
  35   '';
  36
  37   dontWrapQtApps = args.dontWrapQtApps or true;
  38
  39   postFixup = ''
  40     if [ -d "''${!outputDev}/lib/pkgconfig" ]; then
  41         find "''${!outputDev}/lib/pkgconfig" -name '*.pc' | while read pc; do
  42             sed -i "$pc" \
  43                 -e "/^prefix=/ c prefix=''${!outputLib}" \
  44                 -e "/^exec_prefix=/ c exec_prefix=''${!outputBin}" \
  45                 -e "/^includedir=/ c includedir=''${!outputDev}/include"
  46         done
  47     fi
  48
  49     moveQtDevTools
  50
  51     ${args.postFixup or ""}
  52   '';
  53
  54   meta = {
  55     homepage = "http://www.qt.io";
  56     description = "A cross-platform application framework for C++";
  57     license = with licenses; [ fdl13 gpl2 lgpl21 lgpl3 ];
  58     maintainers = with maintainers; [ qknight ttuegel periklis bkchr ];
  59     platforms = platforms.unix;
  60   } // (args.meta or {});
  61 })