pkgs/development/libraries/qt-mobility/default.nix

   1 { lib, stdenv, fetchFromGitHub, qt4, libX11, coreutils, bluez, perl }:
   2 # possible additional dependencies: pulseaudio udev networkmanager immerson qmf
   3
   4 stdenv.mkDerivation rec {
   5   version = "1.2.0";
   6   pname = "qt-mobility";
   7   src = fetchFromGitHub {
   8     owner = "qtproject";
   9     repo = "qt-mobility";
  10     rev = "v${version}";
  11     sha256 = "14713pbscysd6d0b9rgm7gg145jzwvgdn22778pf2v13qzvfmy1i";
  12   };
  13
  14   NIX_CFLAGS_COMPILE="-fpermissive";
  15
  16   configurePhase = ''
  17     ./configure -prefix $out
  18   '';
  19
  20   # we need to prevent the 'make install' to want to write to ${qt4}!
  21   # according to thiago#qt@freenode these are used for the QML engine
  22   preBuild = ''
  23     for i in connectivity contacts feedback gallery location multimedia organizer publishsubscribe sensors serviceframework systeminfo; do
  24       substituteInPlace plugins/declarative/$i/Makefile --replace "${qt4}/lib/qt4/imports/" "$out/lib/qt4/imports/"
  25     done
  26   '';
  27
  28   # Features files (*.prf) are not installed on nixos
  29   # https://bugreports.qt-project.org/browse/QTMOBILITY-1085
  30   #  - features/mobility.prf (/tmp/nix-build-9kh12nhf9cyplfwiws96gz414v6wgl67-qt-mobility-1.2.0.drv-0/qt-mobility-opensource-src-1.2.0)
  31
  32   patchPhase = ''
  33     # required to make the configure script work
  34     substituteInPlace configure --replace "/bin/pwd" "${coreutils}/bin/pwd"
  35
  36     # required to make /include generator work
  37     substituteInPlace bin/syncheaders --replace "/usr/bin/perl" "${perl}/bin/perl"
  38
  39     # required to make the -prefix variable parsing work
  40     substituteInPlace bin/pathhelper --replace "/usr/bin/perl" "${perl}/bin/perl"
  41   '';
  42
  43   buildInputs = [ qt4 libX11 bluez perl ];
  44
  45   meta = with lib; {
  46     description = "Qt Mobility";
  47     homepage = "http://qt.nokia.com/products/qt-addons/mobility";
  48     maintainers = [ maintainers.qknight ];
  49     platforms = platforms.linux;
  50     license = with licenses; [ bsd3 fdl13 gpl3 lgpl21 ];
  51   };
  52 }
  53
  54