pkgs/development/libraries/smpeg/default.nix

   1 { lib, stdenv, fetchsvn, SDL, autoconf, automake, libtool, gtk2, m4, pkg-config, libGLU, libGL, makeWrapper }:
   2
   3 stdenv.mkDerivation rec {
   4   name = "smpeg-svn${version}";
   5   version = "390";
   6
   7   src = fetchsvn {
   8     url = "svn://svn.icculus.org/smpeg/trunk";
   9     rev = version;
  10     sha256 = "0ynwn7ih5l2b1kpzpibns9bb9wzfjak7mgrb1ji0dkn2q5pv6lr0";
  11   };
  12
  13   patches = [
  14     ./format.patch
  15     ./gcc6.patch
  16     ./libx11.patch
  17   ];
  18
  19   enableParallelBuilding = true;
  20
  21   buildInputs = [ SDL gtk2 libGLU libGL ];
  22
  23   nativeBuildInputs = [ autoconf automake libtool m4 pkg-config makeWrapper ];
  24
  25   preConfigure = ''
  26     touch NEWS AUTHORS ChangeLog
  27     sh autogen.sh
  28   '';
  29
  30   postInstall = ''
  31     sed -i -e 's,"SDL.h",<SDL/SDL.h>,' \
  32     -e 's,"SDL_mutex.h",<SDL/SDL_mutex.h>,' \
  33     -e 's,"SDL_audio.h",<SDL/SDL_audio.h>,' \
  34     -e 's,"SDL_thread.h",<SDL/SDL_thread.h>,' \
  35     -e 's,"SDL_types.h",<SDL/SDL_types.h>,' \
  36       $out/include/smpeg/*.h
  37
  38     wrapProgram $out/bin/smpeg-config \
  39       --prefix PATH ":" "${pkg-config}/bin" \
  40       --prefix PKG_CONFIG_PATH ":" "${SDL.dev}/lib/pkgconfig"
  41   '';
  42
  43   NIX_LDFLAGS = "-lX11";
  44
  45   meta = {
  46     homepage = "http://icculus.org/smpeg/";
  47     description = "MPEG decoding library";
  48     license = lib.licenses.gpl2Plus;
  49     platforms = lib.platforms.unix;
  50   };
  51 }