pkgs/tools/misc/fzf/default.nix

   1 { lib, buildGoModule, fetchFromGitHub, writeText, runtimeShell, ncurses, perl }:
   2
   3 buildGoModule rec {
   4   pname = "fzf";
   5   version = "0.27.0";
   6
   7   src = fetchFromGitHub {
   8     owner = "junegunn";
   9     repo = pname;
  10     rev = version;
  11     sha256 = "sha256-q0rAAD6du0WLcd46LUpkG3gBIvmtOE/foEMW5QCoIak=";
  12   };
  13
  14   vendorSha256 = "sha256-FKDCIotyra/TZ48wbpzudJZ2aI2pn+ZR4EoZ+9+19Mw=";
  15
  16   outputs = [ "out" "man" ];
  17
  18   fishHook = writeText "load-fzf-keybindings.fish" "fzf_key_bindings";
  19
  20   buildInputs = [ ncurses ];
  21
  22   buildFlagsArray = [
  23     "-ldflags=-s -w -X main.version=${version} -X main.revision=${src.rev}"
  24   ];
  25
  26   # The vim plugin expects a relative path to the binary; patch it to abspath.
  27   postPatch = ''
  28     sed -i -e "s|expand('<sfile>:h:h')|'$out'|" plugin/fzf.vim
  29
  30     if ! grep -q $out plugin/fzf.vim; then
  31         echo "Failed to replace vim base_dir path with $out"
  32         exit 1
  33     fi
  34
  35     # Has a sneaky dependency on perl
  36     # Include first args to make sure we're patching the right thing
  37     substituteInPlace shell/key-bindings.zsh \
  38       --replace " perl -ne " " ${perl}/bin/perl -ne "
  39     substituteInPlace shell/key-bindings.bash \
  40       --replace " perl -n " " ${perl}/bin/perl -n "
  41   '';
  42
  43   preInstall = ''
  44     mkdir -p $out/share/fish/{vendor_functions.d,vendor_conf.d}
  45     cp shell/key-bindings.fish $out/share/fish/vendor_functions.d/fzf_key_bindings.fish
  46     cp ${fishHook} $out/share/fish/vendor_conf.d/load-fzf-key-bindings.fish
  47   '';
  48
  49   postInstall = ''
  50     cp bin/fzf-tmux $out/bin
  51
  52     mkdir -p $man/share/man
  53     cp -r man/man1 $man/share/man
  54
  55     mkdir -p $out/share/vim-plugins/${pname}
  56     cp -r plugin $out/share/vim-plugins/${pname}
  57
  58     cp -R shell $out/share/fzf
  59     cat <<SCRIPT > $out/bin/fzf-share
  60     #!${runtimeShell}
  61     # Run this script to find the fzf shared folder where all the shell
  62     # integration scripts are living.
  63     echo $out/share/fzf
  64     SCRIPT
  65     chmod +x $out/bin/fzf-share
  66   '';
  67
  68   meta = with lib; {
  69     homepage = "https://github.com/junegunn/fzf";
  70     description = "A command-line fuzzy finder written in Go";
  71     license = licenses.mit;
  72     maintainers = with maintainers; [ Br1ght0ne ma27 zowoq ];
  73     platforms = platforms.unix;
  74     changelog = "https://github.com/junegunn/fzf/blob/${version}/CHANGELOG.md";
  75   };
  76 }