pkgs/tools/misc/partition-manager/default.nix

   1 { mkDerivation, fetchurl, lib, makeWrapper
   2 , extra-cmake-modules, kdoctools, wrapGAppsHook, wrapQtAppsHook
   3 , kconfig, kcrash, kinit, kpmcore
   4 , cryptsetup, lvm2, mdadm, smartmontools, systemdMinimal, util-linux
   5 , btrfs-progs, dosfstools, e2fsprogs, exfat, f2fs-tools, fatresize, hfsprogs
   6 , jfsutils, nilfs-utils, ntfs3g, reiser4progs, reiserfsprogs, udftools, xfsprogs, zfs
   7 }:
   8
   9 let
  10   # External programs are resolved by `partition-manager` and then
  11   # invoked by `kpmcore_externalcommand` from `kpmcore` as root.
  12   # So these packages should be in PATH of `partition-manager`.
  13   # https://github.com/KDE/kpmcore/blob/06f15334ecfbe871730a90dbe2b694ba060ee998/src/util/externalcommand_whitelist.h
  14   runtimeDeps = lib.makeBinPath [
  15     cryptsetup
  16     lvm2
  17     mdadm
  18     smartmontools
  19     systemdMinimal
  20     util-linux
  21
  22     btrfs-progs
  23     dosfstools
  24     e2fsprogs
  25     exfat
  26     f2fs-tools
  27     fatresize
  28     hfsprogs
  29     jfsutils
  30     nilfs-utils
  31     ntfs3g
  32     reiser4progs
  33     reiserfsprogs
  34     udftools
  35     xfsprogs
  36     zfs
  37
  38     # FIXME: Missing command: tune.exfat hfsck hformat fsck.nilfs2 {fsck,mkfs,debugfs,tunefs}.ocfs2
  39   ];
  40
  41 in mkDerivation rec {
  42   pname = "partitionmanager";
  43   # NOTE: When changing this version, also change the version of `kpmcore`.
  44   version = "4.2.0";
  45
  46   src = fetchurl {
  47     url = "mirror://kde/stable/${pname}/${version}/src/${pname}-${version}.tar.xz";
  48     hash = "sha256-6Qlt1c47Eek6TkWWBzTyBZYJ1jfhtwsC9X5q5h6IhPg=";
  49   };
  50
  51   nativeBuildInputs = [ extra-cmake-modules kdoctools wrapGAppsHook wrapQtAppsHook makeWrapper ];
  52
  53   propagatedBuildInputs = [ kconfig kcrash kinit kpmcore ];
  54
  55   postFixup = ''
  56     wrapProgram $out/bin/partitionmanager \
  57       --prefix PATH : "${runtimeDeps}"
  58   '';
  59
  60   meta = with lib; {
  61     description = "KDE Partition Manager";
  62     license = with licenses; [ cc-by-40 cc0 gpl3Plus lgpl3Plus mit ];
  63     homepage = "https://www.kde.org/applications/system/kdepartitionmanager/";
  64     maintainers = with maintainers; [ peterhoeg oxalica ];
  65   };
  66 }