pkgs/tools/misc/staruml/default.nix

   1 { stdenv, lib, fetchurl, makeWrapper
   2 , dpkg, patchelf
   3 , gtk2, glib, gdk-pixbuf, alsaLib, nss, nspr, GConf, cups, libgcrypt, dbus, systemd
   4 , libXdamage, expat }:
   5
   6 let
   7   LD_LIBRARY_PATH = lib.makeLibraryPath
   8     [ glib gtk2 gdk-pixbuf alsaLib nss nspr GConf cups libgcrypt dbus libXdamage expat ];
   9 in
  10 stdenv.mkDerivation rec {
  11   version = "2.8.1";
  12   pname = "staruml";
  13
  14   src =
  15     if stdenv.hostPlatform.system == "i686-linux" then fetchurl {
  16       url = "https://s3.amazonaws.com/staruml-bucket/releases-v2/StarUML-v${version}-32-bit.deb";
  17       sha256 = "0vb3k9m3l6pmsid4shlk0xdjsriq3gxzm8q7l04didsppg0vvq1n";
  18     } else fetchurl {
  19       url = "https://s3.amazonaws.com/staruml-bucket/releases-v2/StarUML-v${version}-64-bit.deb";
  20       sha256 = "05gzrnlssjkhyh0wv019d4r7p40lxnsa1sghazll6f233yrqmxb0";
  21     };
  22
  23   nativeBuildInputs = [ makeWrapper dpkg ];
  24
  25   unpackPhase = ''
  26     mkdir pkg
  27     dpkg-deb -x $src pkg
  28     sourceRoot=pkg
  29   '';
  30
  31   installPhase = ''
  32     mkdir $out
  33     mv opt/staruml $out/bin
  34
  35     mkdir -p $out/lib
  36     ln -s ${stdenv.cc.cc.lib}/lib/libstdc++.so.6 $out/lib/
  37     ln -s ${lib.getLib systemd}/lib/libudev.so.1 $out/lib/libudev.so.0
  38
  39     for binary in StarUML Brackets-node; do
  40       ${patchelf}/bin/patchelf \
  41         --interpreter "$(cat $NIX_CC/nix-support/dynamic-linker)" \
  42         $out/bin/$binary
  43       wrapProgram $out/bin/$binary \
  44         --prefix LD_LIBRARY_PATH : $out/lib:${LD_LIBRARY_PATH}
  45     done
  46   '';
  47
  48   meta = with lib; {
  49     description = "A sophisticated software modeler";
  50     homepage = "https://staruml.io/";
  51     license = licenses.unfree;
  52     platforms = [ "i686-linux" "x86_64-linux" ];
  53   };
  54 }