pkgs/tools/networking/gnirehtet/default.nix

   1 { lib, stdenv, rustPlatform, fetchFromGitHub, fetchzip, androidenv, makeWrapper }:
   2 let
   3 version = "2.5";
   4 apk = stdenv.mkDerivation {
   5   pname = "gnirehtet.apk";
   6   inherit version;
   7   src = fetchzip {
   8     url = "https://github.com/Genymobile/gnirehtet/releases/download/v${version}/gnirehtet-rust-linux64-v${version}.zip";
   9     sha256 = "1db0gkg5z8lighhkyqfsr9jiacrck89zmfnmp74vj865hhxgjzgq";
  10   };
  11   installPhase = ''
  12     mkdir $out
  13     mv gnirehtet.apk $out
  14   '';
  15 };
  16 in
  17 rustPlatform.buildRustPackage {
  18   pname = "gnirehtet";
  19   inherit version;
  20
  21   src = fetchFromGitHub {
  22       owner = "Genymobile";
  23       repo = "gnirehtet";
  24       rev = "v${version}";
  25       sha256 = "0wk6n082gnj9xk46n542h1012h8gyhldca23bs7vl73g0534g878";
  26   };
  27   sourceRoot = "source/relay-rust";
  28   cargoSha256 = "0i7f52r697gjw30m8k60hd3y6wsn5lpz419r083a1rhpbinzd26q";
  29
  30   nativeBuildInputs = [ makeWrapper ];
  31
  32   postInstall = ''
  33     wrapProgram $out/bin/gnirehtet \
  34     --set GNIREHTET_APK ${apk}/gnirehtet.apk \
  35     --set ADB ${androidenv.androidPkgs_9_0.platform-tools}/bin/adb
  36   '';
  37
  38   meta = with lib; {
  39     description = "Reverse tethering over adb for Android";
  40     longDescription = ''
  41       This project provides reverse tethering over adb for Android: it allows devices to use the internet connection of the computer they are plugged on. It does not require any root access (neither on the device nor on the computer).
  42
  43       This relies on adb, make sure you have the required permissions/udev rules.
  44     '';
  45     homepage = "https://github.com/Genymobile/gnirehtet";
  46     license = licenses.asl20;
  47     maintainers = with maintainers; [ symphorien ];
  48     platforms = platforms.unix;
  49   };
  50 }
  51