pkgs/by-name/al/alice-lg/package.nix

   1 {
   2   lib,
   3   fetchFromGitHub,
   4   buildGoModule,
   5   fetchYarnDeps,
   6   stdenv,
   7   gitUpdater,
   8   yarn,
   9   nodejs,
  10   nixosTests,
  11   fixup-yarn-lock,
  12 }:
  13
  14 buildGoModule rec {
  15   pname = "alice-lg";
  16   version = "6.1.0";
  17
  18   src = fetchFromGitHub {
  19     owner = "alice-lg";
  20     repo = "alice-lg";
  21     rev = version;
  22     hash = "sha256-BbwTLHDtpa8HCECIiy+UxyQiLf9iAD2GzE0azXk7QGU=";
  23   };
  24
  25   vendorHash = "sha256-8N5E1CW5Z7HujwXRsZLv7y4uNOJkjj155kmX9PCjajQ=";
  26
  27   passthru.ui = stdenv.mkDerivation {
  28     pname = "alice-lg-ui";
  29     src = "${src}/ui";
  30     inherit version;
  31
  32     yarnOfflineCache = fetchYarnDeps {
  33       yarnLock = src + "/ui/yarn.lock";
  34       hash = "sha256-PwByNIegKYTOT8Yg3nDMDFZiLRVkbX07z99YaDiBsIY=";
  35     };
  36
  37     nativeBuildInputs = [
  38       nodejs
  39       yarn
  40       fixup-yarn-lock
  41     ];
  42
  43     configurePhase = ''
  44       runHook preConfigure
  45
  46       # Yarn and bundler wants a real home directory to write cache, config, etc to
  47       export HOME=$NIX_BUILD_TOP/fake_home
  48
  49       # Make yarn install packages from our offline cache, not the registry
  50       yarn config --offline set yarn-offline-mirror $yarnOfflineCache
  51
  52       # Fixup "resolved"-entries in yarn.lock to match our offline cache
  53       fixup-yarn-lock yarn.lock
  54
  55       yarn install --offline --frozen-lockfile --ignore-scripts --no-progress --non-interactive
  56       patchShebangs node_modules/
  57       runHook postConfigure
  58     '';
  59
  60     buildPhase = ''
  61       runHook preBuild
  62
  63       ./node_modules/.bin/react-scripts build
  64
  65       runHook postBuild
  66     '';
  67
  68     installPhase = ''
  69       runHook preInstall
  70
  71       mv build $out
  72
  73       runHook postInstall
  74     '';
  75   };
  76
  77   preBuild = ''
  78     cp -R ${passthru.ui}/ ui/build/
  79   '';
  80
  81   subPackages = [ "cmd/alice-lg" ];
  82   doCheck = false;
  83
  84   passthru = {
  85     tests = nixosTests.alice-lg;
  86     updateScript = gitUpdater { };
  87   };
  88
  89   meta = {
  90     homepage = "https://github.com/alice-lg/alice-lg";
  91     description = "Looking-glass for BGP sessions";
  92     changelog = "https://github.com/alice-lg/alice-lg/blob/main/CHANGELOG.md";
  93     license = lib.licenses.bsd3;
  94     maintainers = with lib.maintainers; [ stv0g ];
  95     mainProgram = "alice-lg";
  96   };
  97 }