pkgs/by-name/bu/bubblemail/package.nix

   1 { lib
   2 , fetchFromGitLab
   3 , gettext
   4 , gtk3
   5 , python3Packages
   6 , gdk-pixbuf
   7 , libnotify
   8 , gst_all_1
   9 , libsecret
  10 , wrapGAppsHook3
  11 , gsettings-desktop-schemas
  12 , gnome-online-accounts
  13 , glib
  14 , gobject-introspection
  15 , folks
  16 , bash
  17 }:
  18
  19 python3Packages.buildPythonApplication rec {
  20   pname = "bubblemail";
  21   version = "1.4";
  22
  23   src = fetchFromGitLab {
  24     domain = "framagit.org";
  25     owner = "razer";
  26     repo = "bubblemail";
  27     rev = "v${version}";
  28     sha256 = "sha256-MPl4pXvdhwCFWTepn/Mxp8ZMs+HCzXC59qdKZp3mHdw=";
  29   };
  30
  31   buildInputs = [
  32     gtk3
  33     gdk-pixbuf
  34     glib
  35     libnotify
  36     gst_all_1.gstreamer
  37     gst_all_1.gst-plugins-base
  38     gst_all_1.gst-plugins-good
  39     gst_all_1.gst-plugins-bad
  40     libsecret
  41     gnome-online-accounts
  42     folks
  43     bash
  44   ];
  45
  46   nativeBuildInputs = [
  47     gettext
  48     wrapGAppsHook3
  49     python3Packages.pillow
  50     # For setup-hook
  51     gobject-introspection
  52   ];
  53
  54   propagatedBuildInputs = with python3Packages; [
  55     gsettings-desktop-schemas
  56     pygobject3
  57     dbus-python
  58     pyxdg
  59   ];
  60
  61   # See https://nixos.org/nixpkgs/manual/#ssec-gnome-common-issues-double-wrapped
  62   dontWrapGApps = true;
  63
  64   preFixup = ''
  65     makeWrapperArgs+=("''${gappsWrapperArgs[@]}")
  66   '';
  67
  68   meta = with lib; {
  69     description = "Extensible mail notification service";
  70     homepage = "http://bubblemail.free.fr/";
  71     license = licenses.gpl2Plus;
  72     platforms = platforms.linux;
  73     maintainers = with maintainers; [ doronbehar ];
  74   };
  75 }