pkgs/by-name/gi/gitaly/package.nix

   1 { lib
   2 , callPackage
   3 , fetchFromGitLab
   4 , buildGoModule
   5 , pkg-config
   6 }:
   7
   8 let
   9   version = "17.3.6";
  10   package_version = "v${lib.versions.major version}";
  11   gitaly_package = "gitlab.com/gitlab-org/gitaly/${package_version}";
  12
  13   git = callPackage ./git.nix { };
  14
  15   commonOpts = {
  16     inherit version;
  17
  18     # nixpkgs-update: no auto update
  19     src = fetchFromGitLab {
  20       owner = "gitlab-org";
  21       repo = "gitaly";
  22       rev = "v${version}";
  23       hash = "sha256-nXblQfr9ml6F5nNz64haN7ub+cuN3eao14N0Y2d3n0Y=";
  24     };
  25
  26     vendorHash = "sha256-spfSOOe+9NGu+2ZbEGb93X3HnANEXYbvP73DD6neIXQ=";
  27
  28     ldflags = [ "-X ${gitaly_package}/internal/version.version=${version}" "-X ${gitaly_package}/internal/version.moduleVersion=${version}" ];
  29
  30     tags = [ "static" ];
  31
  32     doCheck = false;
  33   };
  34
  35   auxBins = buildGoModule ({
  36     pname = "gitaly-aux";
  37
  38     subPackages = [ "cmd/gitaly-hooks" "cmd/gitaly-ssh" "cmd/gitaly-lfs-smudge" "cmd/gitaly-gpg" ];
  39   } // commonOpts);
  40 in
  41 buildGoModule ({
  42   pname = "gitaly";
  43
  44   subPackages = [ "cmd/gitaly" "cmd/gitaly-backup" ];
  45
  46   preConfigure = ''
  47     mkdir -p _build/bin
  48     cp -r ${auxBins}/bin/* _build/bin
  49     for f in ${git}/bin/git-*; do
  50       cp "$f" "_build/bin/gitaly-$(basename $f)";
  51     done
  52   '';
  53
  54   outputs = [ "out" ];
  55
  56   passthru = {
  57     inherit git;
  58   };
  59
  60   meta = with lib; {
  61     homepage = "https://gitlab.com/gitlab-org/gitaly";
  62     description = "Git RPC service for handling all the git calls made by GitLab";
  63     platforms = platforms.linux ++ [ "x86_64-darwin" ];
  64     maintainers = teams.gitlab.members;
  65     license = licenses.mit;
  66   };
  67 } // commonOpts)