pkgs/by-name/qd/qdirstat/package.nix

   1 {
   2   lib,
   3   fetchFromGitHub,
   4   stdenv,
   5   libsForQt5,
   6   coreutils,
   7   xdg-utils,
   8   bash,
   9   makeWrapper,
  10   perlPackages,
  11 }:
  12
  13 stdenv.mkDerivation rec {
  14   pname = "qdirstat";
  15   version = "1.9";
  16
  17   src = fetchFromGitHub {
  18     owner = "shundhammer";
  19     repo = "qdirstat";
  20     rev = version;
  21     hash = "sha256-pwdmltHDNwUMx1FNOoiXl5Pna0zlKqahmicBCN6UVSU=";
  22   };
  23
  24   nativeBuildInputs =
  25     [ makeWrapper ]
  26     ++ (with libsForQt5; [
  27       qmake
  28       wrapQtAppsHook
  29     ]);
  30
  31   buildInputs = [ perlPackages.perl ];
  32
  33   postPatch = ''
  34     substituteInPlace scripts/scripts.pro \
  35       --replace /bin/true ${coreutils}/bin/true
  36
  37     for i in src/SysUtil.cpp src/FileSizeStatsWindow.cpp
  38     do
  39       substituteInPlace $i \
  40         --replace /usr/bin/xdg-open ${xdg-utils}/bin/xdg-open
  41     done
  42     for i in src/Cleanup.cpp src/cleanup-config-page.ui
  43     do
  44       substituteInPlace $i \
  45         --replace /bin/bash ${bash}/bin/bash \
  46         --replace /bin/sh ${bash}/bin/sh
  47     done
  48     substituteInPlace src/StdCleanup.cpp \
  49       --replace /bin/bash ${bash}/bin/bash
  50   '';
  51
  52   qmakeFlags = [ "INSTALL_PREFIX=${placeholder "out"}" ];
  53
  54   postInstall = ''
  55     wrapProgram $out/bin/qdirstat-cache-writer \
  56       --set PERL5LIB "${perlPackages.makePerlPath [ perlPackages.URI ]}"
  57   '';
  58
  59   meta = with lib; {
  60     description = "Graphical disk usage analyzer";
  61     homepage = "https://github.com/shundhammer/qdirstat";
  62     license = licenses.gpl2Plus;
  63     maintainers = with maintainers; [ donovanglover ];
  64     platforms = platforms.linux;
  65     mainProgram = "qdirstat";
  66   };
  67 }