pkgs/by-name/sb/sbt-extras/package.nix

   1 { lib, stdenv, fetchFromGitHub, which, curl, makeWrapper, jdk, writeScript
   2 , common-updater-scripts, cacert, git, nixfmt-classic, nix, jq, coreutils
   3 , gnused }:
   4
   5 stdenv.mkDerivation rec {
   6   pname = "sbt-extras";
   7   rev = "408f74841b90169a7f674955389212e2d02f7f4d";
   8   version = "2024-09-28";
   9
  10   src = fetchFromGitHub {
  11     owner = "paulp";
  12     repo = "sbt-extras";
  13     inherit rev;
  14     sha256 = "2iXNs2Ks54Gj6T6PR5AtWrmR9uUxgFScAfek2v+qdTo=";
  15   };
  16
  17   dontBuild = true;
  18
  19   nativeBuildInputs = [ makeWrapper ];
  20
  21   installPhase = ''
  22     runHook preInstall
  23
  24     mkdir -p $out/bin
  25
  26     substituteInPlace bin/sbt --replace 'declare java_cmd="java"' 'declare java_cmd="${jdk}/bin/java"'
  27
  28     install bin/sbt $out/bin
  29
  30     wrapProgram $out/bin/sbt --prefix PATH : ${lib.makeBinPath [ which curl ]}
  31
  32     runHook postInstall
  33   '';
  34
  35   doInstallCheck = true;
  36   installCheckPhase = ''
  37     $out/bin/sbt -h >/dev/null
  38   '';
  39
  40   passthru.updateScript = writeScript "update.sh" ''
  41      #!${stdenv.shell}
  42      set -xo errexit
  43      PATH=${
  44        lib.makeBinPath [
  45          common-updater-scripts
  46          curl
  47          cacert
  48          git
  49          nixfmt-classic
  50          nix
  51          jq
  52          coreutils
  53          gnused
  54        ]
  55      }
  56     oldVersion="$(nix-instantiate --eval -E "with import ./. {}; lib.getVersion ${pname}" | tr -d '"')"
  57      latestSha="$(curl -L -s https://api.github.com/repos/paulp/sbt-extras/commits\?sha\=master\&since\=$oldVersion | jq -r '.[0].sha')"
  58     if [ ! "null" = "$latestSha" ]; then
  59        nixpkgs="$(git rev-parse --show-toplevel)"
  60        default_nix="$nixpkgs/pkgs/development/tools/build-managers/sbt-extras/default.nix"
  61        latestDate="$(curl -L -s https://api.github.com/repos/paulp/sbt-extras/commits/$latestSha | jq '.commit.committer.date' | sed 's|"\(.*\)T.*|\1|g')"
  62        update-source-version ${pname} "$latestSha" --version-key=rev
  63        update-source-version ${pname} "$latestDate" --ignore-same-hash
  64        nixfmt "$default_nix"
  65      else
  66        echo "${pname} is already up-to-date"
  67      fi
  68   '';
  69
  70   meta = {
  71     description =
  72       "A more featureful runner for sbt, the simple/scala/standard build tool";
  73     homepage = "https://github.com/paulp/sbt-extras";
  74     license = lib.licenses.bsd3;
  75     maintainers = with lib.maintainers; [ nequissimus puffnfresh ];
  76     mainProgram = "sbt";
  77     platforms = lib.platforms.unix;
  78   };
  79 }